Excel Choosecols -Funktion, um Spalten aus Array oder Bereich abzurufen

In diesem Tutorial werden Sie eine neue Dynamic Array -Funktion von Excel 365 mit dem Namen choosecols vorgestellt und zeigen, wie Sie sie verwenden können, um bestimmte Spalten aus einem Array zu extrahieren.

Stellen Sie sich vor, Sie arbeiten mit einem Datensatz von Hunderten oder Tausenden von Spalten. Offensichtlich sind einige Spalten wichtiger als andere, und natürlich möchten Sie zuerst ihre Daten lesen. Excel 365 bietet eine perfekte Funktion für den Job, mit dem Sie sich sofort aus einem Array bestimmte bestimmte finden können, sodass Sie sich auf die relevantesten Informationen konzentrieren können.

• Excel Choosecols Funktion
• So verwenden Sie die Option Choosecols -Funktion in Excel
• Return Last N Spalten aus Reichweite
• Holen Sie sich jede andere Spalte
• Flip -Array horizontal
• Spalten basierend auf String mit Zahlen abrufen
• Spalten aus mehreren Arrays extrahieren
• Excel Choosecols funktioniert nicht

Excel Choosecols Funktion

Die Choosecols -Funktion in Excel ist so konzipiert, dass sie die angegebenen Spalten aus einem Array oder Bereich zurückgeben.

Die Syntax enthält die folgenden Argumente:

Choosecols (Array, col_num1, [col_num2],…)

Wo:

Array (erforderlich) - das Quellarray oder Bereich.

Col_num1 (erforderlich) - Eine Ganzzahl, die die erste Spalte angibt, die zurückgegeben werden soll.

Col_num2 ,… (optional) - Indexnummern zusätzlicher Spalten, die zurückgegeben werden sollen.

Auf diese Weise können die Funktion der Choosecols in Ihrem Excel aussehen:

Die Verfügbarkeit von Choosecols Funktion

Derzeit ist die Choosecols -Funktion in Excel für Microsoft 365 (Windows und Mac) und Excel für das Web verfügbar.

Tipp. Um einige Zeilen aus einem Bereich oder Array zu extrahieren, kann die Funktion der ChooSerows nützlich sein.

So verwenden Sie die Option Choosecols -Funktion in Excel

Choosecols ist eine dynamische Array -Funktion, sodass sie die Arrays nativ behandelt. Die Formel soll in nur einer Zelle eingegeben werden - die obere linke Zelle des Zielbereichs - und übergibt automatisch in so viele Spalten wie angegeben. Das Ergebnis ist ein einzelnes dynamisches Array, das als Verschüttungsbereich bezeichnet wird.

Um eine Choosecols -Formel in Excel zu erstellen, müssen Sie dies tun:

1. Liefern Sie für Array einen Zellbereich oder eine Reihe von Werten.
2. Geben Sie für col_num eine positive oder negative Ganzzahl an, die angibt, welche Spalte zurückgegeben werden soll. Eine positive Zahl zieht eine entsprechende Spalte von der linken Seite des Arrays, eine negative Zahl - von der rechten Seite des Arrays. Um mehrere Spalten zu erhalten, können Sie ihre Zahlen in separaten Argumenten oder in einem Argument in Form einer Array -Konstante definieren.

Um beispielsweise Spalten 2, 3 und 4 aus dem Bereich A4: E19 zu erhalten, lautet die Formel:

=CHOOSECOLS(A4:E19, 2, 3, 4)

Alternativ können Sie eine horizontale Array -Konstante wie {2,3,4} oder eine vertikale Array -Konstante wie {2; 3; 4} verwenden, um die Spaltenzahlen anzugeben:

=CHOOSECOLS(A4:E19, {2,3,4})

=CHOOSECOLS(A4:E19, {2;3;4})

Alle drei obigen Formeln liefern das gleiche Ergebnis:

In einigen Situationen ist es möglicherweise bequemer, die Säulenzahlen in einigen Zellen einzugeben und dann auf diese Zellen einzeln zu verweisen oder eine einzelne Reichweite zu liefern. Zum Beispiel:

=CHOOSECOLS(A4:E19, G4, H4, I4)

=CHOOSECOLS(A4:E19, G4:I4)

Dieser Ansatz gibt Ihnen mehr Flexibilität - um andere Spalten zu extrahieren, geben Sie einfach verschiedene Zahlen in die vordefinierten Zellen ein, ohne die Formel selbst zu modifizieren.

Nachdem Sie das Nötigste kennen, tauchen wir in die Extras ein und erkunden Sie eine etwas komplexere Choosecols -Formeln, um bestimmte Szenarien zu bewältigen.

Holen Sie sich die letzten Spalten aus Reichweite

Um eine oder mehrere Spalten vom Ende eines Bereichs zurückzugeben, liefern Sie negative Zahlen für die Argumente col_num . Dadurch wird die Funktion von der rechten Seite des Arrays beginnt, Spalten von der rechten Seite zu zählen.

Verwenden Sie beispielsweise diese Formel, um die letzte Spalte aus dem Bereich zu erhalten:

=CHOOSECOLS(A4:E19, -1)

Um die letzten beiden Spalten zu extrahieren, verwenden Sie diese:

=CHOOSECOLS(A4:E19, -2, -1)

Um die letzten 2 Spalten in umgekehrter Reihenfolge zurückzugeben, ändern Sie die Reihenfolge der COL_NUM -Argumente wie folgt:

=CHOOSECOLS(A4:E19, -1, -2)

Holen Sie sich jede andere Spalte in Excel

Um jede andere Spalte aus einem bestimmten Bereich zu extrahieren, können Sie Choosecols zusammen mit mehreren anderen Funktionen verwenden. Unten finden Sie zwei Versionen der Formel zum Extrahieren von ungeraden und sogar Säulen.

Um seltsame Spalten (wie 1, 3, 5 usw.) zu erhalten, lautet die Formel:

=CHOOSECOLS(A4:E19, SEQUENCE(ROUNDUP(COLUMNS(A4:E19)/2, 0), 1, 1, 2))

Um auch Spalten zurückzugeben (z. B. 2, 4, 6 usw.), nimmt die Formel dieses Formular an:

=CHOOSECOLS(A4:E19, SEQUENCE(ROUNDDOWN(COLUMNS(A4:E19)/2, 0), 1, 2, 2))

Der folgende Screenshot zeigt die erste Formel in Aktion:

Wie diese Formel funktioniert:

Kurze Erläuterung : Die Option Choosecols -Funktion gibt jede andere Spalte basierend auf einem Array von sequentiellen ungeraden oder sogar Zahlen zurück, die von der Sequenzfunktion erzeugt werden.

Eine detaillierte Formel-Aufschlüsselung :

Der erste Schritt besteht darin, zu berechnen, wie viele Spalten zurückkehren sollen. Dafür verwenden wir eine dieser Formeln:

ROUNDUP(COLUMNS(A4:E19)/2, 0)

oder

ROUNDDOWN(COLUMNS(A4:E19)/2, 0)

Die Spalten zählen die Gesamtzahl der Spalten im Quellbereich. Sie teilen diese Zahl durch 2 und dann, je nachdem, ob Sie ungerade oder sogar Säulen extrahieren, mit Hilfe von Roundup oder Rounddown den Quotienten entweder nach oben oder nach unten zur Ganzzahl. Rundung ist erforderlich, falls der Quellbereich eine ungerade Anzahl von Säulen enthält, wodurch ein Rest durch 2 geteilt wird.

Unser Quellbereich hat 5 Spalten. Für ungerade Säulen Runden (5/2, 0) kehrt 3 zurück, während für sogar Spalten Rounddown (5/2, 0) 2 zurückgibt.

Die zurückgegebene Nummer wird dem ersten Argument ( Zeilen ) der Sequenzfunktion zugestellt.

Für seltsame Spalten bekommen wir:

SEQUENCE(3, 1, 1, 2)

Diese Sequenzformel erzeugt ein Array von Zahlen, die aus 3 Zeilen und 1 Spalte bestehen, beginnend mit 1 und durch 2, das {1; 3; 5} ist.

Für auch Spalten haben wir:

SEQUENCE(2, 1, 2, 2)

In diesem Fall erzeugt die Sequenz ein Array von Zahlen, die aus 2 Zeilen und 1 Spalte bestehen, beginnend mit 2 und durch 2 erhöht, was {2; 4} ist.

Das obige Array geht an das Argument von Choosecols Col_Num1 , und Sie erhalten das gewünschte Ergebnis.

Drehen Sie ein Array horizontal in Excel um

Um die Reihenfolge der Spalten in einem Array von links nach rechts umzukehren, können Sie auf diese Weise die Funktionen von Choosecols, Sequence und Spalten zusammenstellen:

=CHOOSECOLS(A4:D19, SEQUENCE(COLUMNS(A4:D19)) *-1)

Infolgedessen wird der ursprüngliche Bereich horizontal wie im folgenden Bild gezeigt:

Wie diese Formel funktioniert:

Hier verwenden wir die Sequenzfunktion, um ein Array zu generieren, das so viele sequentielle Zahlen enthält, wie Spalten im Quellarray vorhanden sind. Dafür nisten wir Spalten (A4: D13) im Argument der Zeilen :

SEQUENCE(COLUMNS(A4:D19))

Die anderen Argumente ( Spalten , Start , Schritt ) werden weggelassen, sodass sie standardmäßig 1. Infolgedessen erzeugt die Sequenz ein Array von sequentiellen Zahlen wie 1, 2, 3,…, n, wobei n der Index der letzten Spalte im Array ist. Um die Option Choosecols zu zwingen, die Spalten von rechts nach links zu zählen, multiplizieren wir jedes Element der erzeugten Sequenz mit -1. Infolgedessen erhalten wir eine Reihe negativer Zahlen wie {-1; -2; -3}, die zum Col_Num- Argument von Choosecols gehen und sie anweisen, die entsprechenden Spalten von der rechten Seite des Arrays zurückzugeben:

CHOOSECOLS(A4:D19, {-1;-2;-3;-4})

Spalten basierend auf String mit Zahlen extrahieren

In Situation, in der die Indexnummern der Zielspalten in Form einer Textzeichenfolge bereitgestellt werden, können Sie mit der Textesplit -Funktion die Zeichenfolge durch einen bestimmten Trennzeichen teilen und dann das resultierende Array von Zahlen an Choosecols übergeben.

Nehmen wir an, die Spaltennummern sind in Zelle H3 aufgeführt, die durch ein Komma und einen Raum getrennt sind. Verwenden Sie diese Formel, um die interessierenden Spalten zu erhalten:

=CHOOSECOLS(A4:E19, TEXTSPLIT(H3, ", ") *1)

Wie diese Formel funktioniert:

Zunächst teilen Sie eine Zeichenfolge durch einen bestimmten Trennzeichen (ein Komma und einen Raum in unserem Fall):

TEXTSPLIT(H3, ", ")

Ein Zwischenergebnis ist ein Array von Textwerten wie {"1", "4", "5"}. Um Text in Zahlen umzuwandeln, multiplizieren Sie die Array -Elemente mit 1 oder führen Sie einen anderen Mathematikvorgang aus, der die ursprünglichen Werte nicht ändert.

TEXTSPLIT(H3, ", ") *1

Dies erzeugt eine Reihe von numerischen Werten {1,4,5}, die die Funktion der Choosecols verarbeiten kann, und Sie erhalten das Ergebnis, nach dem Sie suchen:

CHOOSECOLS(A4:E19, {1,4,5})

Spalten aus mehreren Bereichen extrahieren

Um bestimmte Spalten aus mehreren nicht-intierenden Bereichen zu erhalten, fusionieren Sie zuerst alle Bereiche mit Hilfe der VStack-Funktion in einen und verarbeiten dann den zusammengeführten Bereich mit Choosecols.

Um beispielsweise die Spalten 1 und 3 aus den Bereichen A4: D8, A12: D15 und A19: D21 zurückzugeben, lautet die Formel:

=CHOOSECOLS(VSTACK(A4:D8, A12:D15, A19:D21), 1, 3)

Choosecols funktionieren nicht

Wenn die Choosecols -Formel einen Fehler verursacht, ist es am wahrscheinlichsten, dass es eines der folgenden ist.

#WERT! Fehler

Tritt auf, wenn der Absolutwert eines Col_num -Arguments Null oder größer ist als die Gesamtzahl der Spalten im verwiesenen Array.

#NAME? Fehler

Tritt auf, wenn der Name der Funktion falsch geschrieben ist oder die Funktion in Ihrer Excel -Version nicht verfügbar ist. Derzeit wird Choosecols nur in Excel 365 und Excel für das Web unterstützt. Weitere Informationen finden Sie unter Hinweis, wie Sie #Name -Fehler in Excel beheben.

#VERSCHÜTTEN! Fehler

Tritt auf, wenn etwas verhindert, dass die Formel die Ergebnisse in benachbarte Zellen verschüttet. Um es zu beheben, löschen Sie einfach die obstrudierenden Zellen. Weitere Informationen finden Sie unter der Behebung von #spill! Fehler in Excel.

So verwenden Sie die Option Choosecols -Funktion in Excel, um bestimmte Spalten aus einem Bereich oder Array zurückzugeben. Vielen Dank für das Lesen und sehen Sie Sie nächste Woche in unserem Blog!

Üben Sie die Arbeitsmappe zum Download

Excel Choosecols Formel - Beispiele (.xlsx -Datei)

Das obige ist der detaillierte Inhalt vonExcel Choosecols -Funktion, um Spalten aus Array oder Bereich abzurufen. Für weitere Informationen folgen Sie bitte anderen verwandten Artikeln auf der PHP chinesischen Website!