Excel ChooSerows funktionieren, um bestimmte Zeilen aus dem Array zu extrahieren

In diesem Tutorial werfen wir einen detaillierten Blick auf die Excel 365-Funktion namens ChooSerows und ihre praktischen Verwendungen.

Angenommen, Sie haben ein Excel -Arbeitsblatt mit Hunderten von Zeilen, aus denen Sie einige spezifische extrahieren möchten, beispielsweise alle seltsamen oder sogar Zeilen, die ersten 5 oder die letzten 10 Zeilen usw. Fühlen Sie sich bereits verärgert über den Gedanken, die Daten manuell zu kopieren und zu kleben oder einen VBA -Code zu schreiben, um die Aufgabe zu automatisieren? Mach dir keine Sorge! Alles ist viel einfacher als es scheint. Verwenden Sie einfach die neue Funktion Dynamic Array ChooSerows.

• Excel ChooSerows Funktion
• So verwenden Sie die Wahl der ChooSerows in Excel
• Return Last N Zeilen von Array zurück
• Jede andere Reihe extrahieren
• Flip Array vertikal
• Zeilen aus mehreren Arrays extrahieren
• Holen Sie sich Zeilen basierend auf String mit Zahlen
• Excel ChooSerows funktioniert nicht

Excel ChooSerows Funktion

Die Option ChooSerows in Excel wird verwendet, um die angegebenen Zeilen aus einem Array oder Bereich zu extrahieren.

Die Syntax ist wie folgt:

ChooSerows (Array, row_num1, [row_num2],…)

Wo:

Array (erforderlich) - Das Quellarray.

Row_num1 (erforderlich) - Eine Ganzzahl, die den numerischen Index der ersten Zeile zurückgibt, die zurückgegeben werden soll.

Row_num2 ,… (optional) - Indexnummern zusätzlicher Zeilen, die zurückgegeben werden sollen.

So funktioniert die Funktion der ChooSerows in Excel 365:

Wahlverfügbarkeit von ChooSerows

Die Option ChooSerows -Funktion ist nur in Excel für Microsoft 365 (Windows und Mac) und Excel für das Web verfügbar.

Tipp. Um bestimmte Spalten aus einem Bereich oder Array abzurufen, verwenden Sie die Option Choosecols -Funktion.

So verwenden Sie die Wahl der ChooSerows in Excel

Um bestimmte Zeilen aus einem bestimmten Array zu ziehen, konstruieren Sie eine ChooSerows -Formel auf diese Weise:

1. Für das Array können Sie eine Reihe von Zellen oder eine Array von Werten liefern, die von einer anderen Formel gesteuert werden.
2. Geben Sie für Row_Num eine positive oder negative Ganzzahl an, die angibt, welche Zeile zurückgegeben werden soll. Eine positive Zahl holt eine entsprechende Zeile vom Start des Arrays, eine negative Zahl - vom Ende des Arrays. Mehrere Zeilennummern können einzeln in getrennten Argumenten oder in einem Argument in Form einer Array -Konstante bereitgestellt werden.

Als Excel -Dynamic Array -Funktion übernimmt ChooSerows Arrays nativ. Sie geben die Formel in die obere linke Zelle des Zielbereichs ein und verteilt nach Bedarf automatisch in so viele Spalten und Zeilen. Das Ergebnis ist ein einzelnes dynamisches Array, das auch als Verschüttungsbereich bezeichnet wird.

Um beispielsweise Zeilen 2, 4, 6, 8 und 10 aus dem Bereich A4: D13 zu erhalten, lautet die Formel:

=CHOOSEROWS(A4:D13, 2, 4, 6, 8, 10)

Alternativ können Sie eine Array -Konstante wie {2,4,6,8,10} oder {2; 4; 6; 6; 8; 10} verwenden, um die gewünschten Zeilen anzugeben:

=CHOOSEROWS(A4:D13, {2,4,6,8,10})

Oder

=CHOOSEROWS(A4:D13, {2;4;6;8;10})

Eine andere Möglichkeit, die Zeilenzahlen zu liefern, besteht darin, sie in separate Zellen einzugeben und dann entweder die einzelnen Zellreferenzen für mehrere Argumente von row_num oder eine Bereichsreferenz für ein einzelnes Row_num -Argument zu verwenden.

Zum Beispiel:

=CHOOSEROWS(A4:D13, F4, G4, H4)

=CHOOSEROWS(A4:D13, F4:H4)

Ein Vorteil dieses Ansatzes besteht darin, dass Sie andere Zeilen extrahieren können, indem Sie einfach die Zahlen in den vordefinierten Zellen ändern, ohne die Formel selbst zu bearbeiten.

Im Folgenden werden einige weitere Beispiele für ChooSerows -Formel erörtert, um spezifischere Anwendungsfälle zu verarbeiten.

Zeilen vom Ende eines Arrays zurückgeben

Um schnell die letzten N -Zeilen aus einem Bereich zu erhalten, geben Sie negative Zahlen für die Argumente row_num an. Dadurch wird die Funktion zum Zählen von Zeilen vom Ende des Arrays gezwungen.

Verwenden Sie beispielsweise die letzte 3 Zeile aus dem Bereich A4: D13, um diese Formel zu verwenden:

=CHOOSEROWS(A4:D13, -3, -2, -1)

Das Ergebnis wird ein 3-Reihen-Array sein, in dem die Zeilen in derselben geordneten geordneten angezeigt werden wie im verwiesenen Bereich.

Um die letzten 3 Zeilen in umgekehrter Reihenfolge von unten nach oben zurückzugeben, ändern Sie die Reihenfolge der ROW_NUM -Argumente wie folgt:

=CHOOSEROWS(A4:D13, -1, -2, -3)

Extrahieren Sie jede andere Reihe aus einem Array in Excel

Verwenden Sie ChooSerows in Kombination mit einigen anderen Funktionen, um jede andere Zeile aus einem bestimmten Bereich zu erhalten. Die Formel variiert leicht, je nachdem, ob Sie ungerade oder sogar Zeilen extrahieren.

Um ungerade Zeilen wie 1, 3, 5,… die Formel in dieser Form zurückzunehmen:

=CHOOSEROWS(A4:D13, SEQUENCE(ROUNDUP(ROWS(A4:D13)/2, 0), 1, 1, 2))

Um auch Zeilen wie 2, 4, 6,… die Formel lautet wie folgt:

=CHOOSEROWS(A4:D13, SEQUENCE(ROUNDDOWN(ROWS(A4:D13)/2, 0), 1, 2, 2))

Wie diese Formel funktioniert:

Im Wesentlichen gibt die Option ChooSerows Zeilen basierend auf einem Array von sequentiellen Odd oder sogar Zahlen zurück, die von der Sequenzfunktion generiert werden. Nachfolgend folgt eine detaillierte Formelaufschlüsselung.

Erstens bestimmen Sie, wie viele Zeilen zurückkehren sollen. Dazu verwenden Sie die Zeilenfunktion, um die Gesamtzahl der Zeilen im referenzierten Array zu erhalten, das Sie durch 2 dividieren, und dann den Quotienten mit Hilfe von Roundup oder Rounddown nach oben oder nach unten zur Ganzzahl. Da diese Zahl später dem Reihenargument der Sequenz zugestellt wird, ist eine Rundung erforderlich, um eine Ganzzahl zu erhalten, falls der Quellbereich eine ungerade Anzahl von Zeilen enthält.

Da unser Quellbereich eine gleichmäßige Anzahl von Zeilen (10) hat, die genau durch 2 geteilt werden, gibt es sowohl Roundup (10/2, 0) als auch Rounddown (10/2, 0) das gleiche Ergebnis zurück, was 5 ist.

Die zurückgegebene Nummer wird der Sequenzfunktion zugestellt.

Für ungerade Zeilen:

SEQUENCE(5, 1, 1, 2)

Für sogar Reihen:

SEQUENCE(5, 1, 2, 2)

Die obige Sequenzformel erzeugt eine Array von Zahlen, die aus 5 Zeilen und 1 Spalte bestehen, beginnend bei 1 für ungerade Zeilen (bei 2 für gleichmäßige Zeilen) und durch 2 erhöht.

Für ungerade Zeilen bekommen wir dieses Array:

{1;3;5;7;9}

Für auch Zeilen bekommen wir das:

{2;4;6;8;10}

Das generierte Array geht an das Argument von Row_Num1 von ChooSerows, und Sie erhalten das gewünschte Ergebnis:

=CHOOSEROWS(A4:D13, {1;3;5;7;9})

Wechseln Sie die Reihenfolge der Reihen in einem Array um

Um ein Array vertikal von oben nach unten zu drehen, können Sie auch die ChooSerows und Sequenzfunktionen zusammen verwenden. Zum Beispiel:

=CHOOSEROWS(A4:D13, SEQUENCE(ROWS(A4:D13))*-1)

In dieser Formel setzen wir nur das erste Argument ( Zeilen ) der Sequenz, das der Gesamtzahl der Zeilen in den anfänglichen Array -Zeilen entspricht (A4: D13). Die ausgelassenen Argumente ( Spalten , Start , Schritt ) standardmäßig 1. Infolgedessen erzeugt die Sequenz ein Array von sequentiellen Zahlen wie 1, 2, 3,…, n, wobei n die letzte Zeile im Quellarray ist. Damit die ChooSerows Zeilen in Abfallrichtung zählen lassen, wird die generierte Sequenz mit -1 multipliziert, sodass das Row_num- Argument ein Array negativer Zahlen wie {-1; -2; -3; -4; -5; -6; -7; -8; -9; -10} erhält.

Infolgedessen wird die Reihenfolge der Elemente in jeder Spalte von oben nach unten geändert:

Zeilen aus mehreren Arrays extrahieren

Um spezifische Zeilen aus zwei oder mehr nicht konzipiösen Bereichen zu erhalten, kombinieren Sie sie zunächst mit der VStack-Funktion und übergeben dann den zusammengeführten Bereich an ChooSerows.

Um die ersten beiden Zeilen aus dem Bereich A4: D8 und die letzten beiden Zeilen aus dem Bereich A12: D16 zu extrahieren, verwenden Sie diese Formel:

=CHOOSEROWS(VSTACK(A4:D8, A12:D16), 1, 2, -2, -1)

Holen Sie sich Zeilen basierend auf einer Zeichenfolge, die Zeilennummern enthält

Dieses Beispiel zeigt, wie bestimmte Zeilen zurückgegeben werden, indem die Zahlen aus einer alpha-numerischen Zeichenfolge extrahiert werden.

Angenommen, Sie haben von Kommas getrennte Zahlen in der Zelle G3, die die interessierenden Zeilen auflisten. Um die Zeilennummern aus einer Zeichenfolge zu extrahieren, verwenden Sie die Funktion von Texten, die eine Textzeichenfolge durch einen bestimmten Trennzeichen (in unserem Fall) teilen kann:

=TEXTSPLIT(G3, ",")

Das Ergebnis ist ein Array von Textwerten wie {"3", "5", "7", "10"}. Führen Sie eine mathematische Operation durch, die die Werte nicht ändert, z. B. 0 oder *1, um es in eine Reihe von Zahlen umzuwandeln.

=TEXTSPLIT(G3, ",") *1

Dies erzeugt die numerische Array -Konstante {3,5,7,10}, die die Funktion der ChooSerows benötigt, sodass Sie die Texsplit -Formel in das ^2. Argument einbinden:

=CHOOSEROWS(A4:D13, TEXTSPLIT(G3, ",") *1)

Infolgedessen werden alle angegebenen Zeilen als einzelnes Array zurückgegeben:

Wahlfunktionen funktionieren nicht

Wenn die ChooSerows -Formel zu einem Fehler führt, ist es höchstwahrscheinlich einer dieser Gründe.

#WERT! Fehler

Tritt auf, wenn der Absolutwert eines Row_num -Arguments Null oder höher ist als die Gesamtzahl der Zeilen im Array.

#NAME? Fehler

Tritt auf, wenn der Name der Funktion falsch geschrieben ist oder die Funktion in Ihrem Excel nicht unterstützt wird. Derzeit ist ChooSerows nur in Excel 365 und Excel für das Web erhältlich. Weitere Informationen finden Sie in Excel.

#VERSCHÜTTEN! Fehler

Tritt auf, wenn nicht genügend leere Zellen mit den Ergebnissen gefüllt werden. Um es zu beheben, löschen Sie einfach die obstrudierenden Zellen. Weitere Informationen finden Sie in Excel #spill! Fehler.

So verwenden Sie die Funktion der ChooSerows in Excel, um bestimmte Zeilen aus einem Bereich oder Array zurückzugeben. Vielen Dank fürs Lesen und ich hoffe, Sie nächste Woche in unserem Blog zu sehen!

Üben Sie die Arbeitsmappe zum Download

Excel ChooSerows Formel - Beispiele (.xlsx -Datei)

Das obige ist der detaillierte Inhalt vonExcel ChooSerows funktionieren, um bestimmte Zeilen aus dem Array zu extrahieren. Für weitere Informationen folgen Sie bitte anderen verwandten Artikeln auf der PHP chinesischen Website!