Excel -Erweiterungsfunktion, um das Array auf bestimmte Abmessungen zu erweitern

Das Tutorial führt eine neue Dynamic Array -Funktion Excel 365 vor, die ein Array mit einem Wert Ihrer Wahl auf die gewünschten Dimensionen erweitern kann.

Möchten Sie ein Array auf eine bestimmte Anzahl von Zeilen oder Spalten erhöhen, damit alle ähnlichen Arrays in Ihrem Arbeitsblatt die gleiche Größe haben? In Excel 365 kann dies mit einer einfachen Formel erfolgen. Treffen Sie die brandneue Erweiterungsfunktion, die ein Array auf alle von Ihnen festgelegten Abmessungen anbauen kann.

• Excel -Erweiterungsfunktion
• So verwenden Sie die Erweiterungsfunktion in Excel
• Erweitern Sie das Array auf eine bestimmte Anzahl von Zeilen
• Erweitern Sie das Array auf eine bestimmte Anzahl von Spalten
• Erweitern Sie ein Array links und hoch
• Split String und Pad Array
• Excel Expand -Funktion funktioniert nicht

Excel -Erweiterungsfunktion

Die Erweiterungsfunktion in Excel ist so konzipiert, dass sie ein Array mit einem Wert Ihrer Wahl für die angegebenen Zeilen- und Spaltenabmessungen padelt.

Die Syntax enthält die folgenden Argumente:

Erweitern (Array, Zeilen, [Spalten], [pad_with])

Wo:

Array (erforderlich) - Das ursprüngliche Array.

Zeilen (optional) - Die Anzahl der Zeilen im zurückgegebenen Array. Wenn weggelassen, werden keine neuen Zeilen hinzugefügt, und das Argument der Spalten muss festgelegt werden.

Spalten (optional) - Die Anzahl der Spalten im zurückgegebenen Array. Wenn weggelassen, werden keine neuen Spalten hinzugefügt, und das Argument der Zeilen muss festgelegt werden.

Pad_with - der Wert, um neue Zellen mit zu füllen. Wenn es weggelassen wird, ist standardmäßig #n/a.

Tipp. Verwenden Sie die Tropfenfunktion, um unerwünschte Zeilen oder Spalten aus einem Array zu entfernen.

Funktionsverfügbarkeit erweitern

Derzeit ist die Erweiterungsfunktion für Microsoft 365 (Windows und Mac) und Excel für das Web in Excel verfügbar.

So verwenden Sie die Erweiterungsfunktion in Excel

Um ein Array auf die gewünschte Größe zu erhöhen, konstruieren Sie eine erweiterte Formel auf diese Weise:

1. Liefern Sie für Array eine Reihe von Zellen oder eine Array von Werten, die von einer anderen Formel zurückgegeben werden.
2. Geben Sie für Zeilen und Spalten positive Zahlen an, die größer sind als die Anzahl der Zeilen und Spalten im ursprünglichen Array. Beachten Sie, dass diese Argumente die Dimensionen des resultierenden Arrays definieren, nicht die Anzahl der zu addierten Zeilen oder Spalten. In jeder bestimmten Formel müssen entweder Zeilen oder Spalten festgelegt werden. Das ausgelassene Argument stellt die entsprechende Dimension (Zeilen oder Spalten) des Quellarrays standardmäßig aus.
3. Geben Sie für PAD_WITH den Wert an, um die neuen Zellen zu füllen, die dem Array hinzugefügt wurden. Wenn es sich um einen Textwert handelt, legen Sie ihn in doppelte Zitate ein. Wenn es sich um einen numerischen Wert handelt, verwenden Sie ihn ohne Anführungszeichen. Wenn nicht zur Verfügung gestellt, werden die neuen Zellen mit dem Fehler #N/A gepolstert.

Als dynamische Array -Funktion muss Expan nur in einer Zelle eingegeben werden und verteilt die Ergebnisse automatisch in so viele Zellen , wie in den Argumenten und Spalten angegeben .

Um beispielsweise das Array C6: D13 auf 12 Zeilen und 3 Spalten zu erweitern, lautet die Formel:

=EXPAND(C6:D13, 12, 3)

Da das Argument von PAD_WITH nicht festgelegt ist, padelt die obige Formel die neu hinzugefügten Zellen mit dem Fehler #n/a. Um das Standardverhalten zu ändern, geben Sie den gewünschten Wert für das Argument PAD_WITH an. Zum Beispiel können Sie die Neuarray -Werte mit einem Bindestrich padeln:

=EXPAND(C6:D13, 12, 3, "-")

Im Folgenden finden Sie einige weitere Beispiele für die Verwendung der Expand -Funktion in Excel, um ein Array in eine bestimmte Richtung zu erweitern.

Erweitern Sie das Array auf eine bestimmte Anzahl von Zeilen

Um ein Array auf die gewünschte Anzahl von Zeilen zu verlängern, definieren Sie das Argument der Zeilen und lassen Sie Spalten weg.

Verwenden Sie beispielsweise diese Formel, um das anfängliche Array auf insgesamt 12 Zeilen zu erhöhen:

=EXPAND(C6:D13, 12, , "-")

Da Spalten nicht erweitert werden sollten, geben wir ein Komma nach Zeilen ein und nach dem Komma den Polsterwert eingeben.

Erweitern Sie das Array auf eine bestimmte Anzahl von Spalten

Um einem Array weitere Spalten hinzuzufügen, definieren Sie das Argument der Spalten und lassen Sie Zeilen weg.

So können Sie zum Beispiel das Quellarray nach rechts erweitern, sodass es insgesamt 4 Spalten enthält:

=EXPAND(A4:C15, , 4, "-")

So erweitern Sie ein Array nach links und hoch

Die Erweiterungsfunktion soll ein Array nach rechts und unten erweitern. Um die Zellen links und oben des Quellarrays hinzuzufügen, müssen Sie Ihre eigene Lösung ausarbeiten.

Angenommen, Sie haben eine Reihe von Werten in B4: C12. Sie wollen links vom ursprünglichen Array 3 Zeilen über und 1 Spalte hinzufügen. Um die Mechanik besser zu verstehen, werden wir zuerst jede Aufgabe einzeln ausführen und dann alle Teile zusammenfügen.

Spalten zu links hinzufügen

Um das Array horizontal zu erweitern, können Sie mit der HStack -Funktion eine bestimmte Anzahl leerer Spalten links in Ihrem Array anhängen. In diesem Beispiel fügen wir 1 leere Spalte mit dieser Formel hinzu:

=HSTACK(D4:D12, B4:C12)

Beachten Sie, dass ein leeres Array, das Sie stapeln (D4: D12), die gleiche Anzahl von Zeilen wie das Quellarray haben sollte und zuerst in der Formel geliefert werden sollte. Infolgedessen wird links vom ursprünglichen Array eine Spalte mit Nullwerten hinzugefügt.

Fügen Sie Zeilen oben hinzu

Um das Array vertikal zu erweitern, nutzen Sie die VStack -Funktion, um eine bestimmte Anzahl leerer Zeilen über der ersten Zeile Ihres ursprünglichen Arrays zu platzieren.

In unserem Fall sind die folgenden zwei Bereiche mit der gleichen Anzahl von Spalten gestapelt, ein leeres Array kommt zuerst:

=VSTACK(B14:C16, B4:C12)

Im Ergebnis werden 3 Zeilen mit Nullwerten an die Oberseite des Anfangsarrays hinzugefügt.

Fügen Sie die Zeilen oben und die Spalten links hinzu

Um ein Array vertikal und horizontal zu erweitern, nisten Sie die VStack und die HStack -Funktion in den anderen. In unserem Fall nimmt die Formel diese Form an:

=VSTACK(B14:D16, HSTACK(D4:D12, B4:C12))

Und erzeugt dieses Ergebnis:

Pad ein Array nach oben und links mit benutzerdefiniertem Wert

Standardmäßig geben die VStack- und HStack -Funktionen Nullen anstelle von leeren Zellen zurück. Um die neuen Zellen mit einem benutzerdefinierten Wert zu padeln, nisten Sie eine Kombination von IF und ISBLANK in jeder Stapelfunktion, die Rohlinge durch den von Ihnen angegebenen Wert ersetzt.

Um beispielsweise die neuen Zellen mit einem Bindestrich zu versehen, lautet die Formel:

=VSTACK(IF(ISBLANK(B14:D16),"-", B14:D16), HSTACK(IF(ISBLANK(D4:D12),"-", D4:D12), B4:C12))

Verwenden Sie diese Formel, um ein Array mit leeren Zellen zu erweitern:

=VSTACK(IF(ISBLANK(B14:D16),"", B14:D16), HSTACK(IF(ISBLANK(D4:D12),"", D4:D12), B4:C12))

Teilen Sie Strings und erweitern Sie Arrays

In diesem Beispiel wird angezeigt, wie die Funktionen für Erweiterungs- und Texten zusammen verwendet werden, um eine Textzeichenfolge durch einen bestimmten Trennzeichen in einzelnen Spalten zu teilen und dann das endgültige Array auf die gewünschte Größe zu erweitern.

Nehmen wir an, Sie haben eine Spalte wie Spalte B im Bild unten. Jede Zeichenfolge hat mehrere Werte, die mit einem bestimmten Trennzeichen getrennt sind (ein Komma und einen Raum in unserem Fall). Ihr Ziel ist es, jede Zeichenfolge in separate Zellen zu teilen, damit alle resultierenden Arrays die gleiche Anzahl von Spalten haben.

Um die Aufgabe zu erfüllen, geben Sie diese Formel in E4 ein:

=EXPAND(TEXTSPLIT(B4, ", "), , COLUMNS(E3:H3), "-")

In dieser Formel:

• Texsplit trennt die Werte in B4 mit einem Komma und einem Raum (",") als Trennzeichen.
• Spalten berechnen die Anzahl der Spalten im Ausgabearray.
• Erweitert erweitert das zurückgegebene Array auf die rechten Polsterung fehlende Werte mit Bindestrichen ("-").

Ziehen Sie die Formel durch E15 und Sie erhalten dieses Ergebnis:

Die Funktion erweitern, funktioniert nicht

Wenn die Erweiterungsfunktion in Ihrem Excel fälschlicherweise funktioniert oder einen Fehler auswirkt, können Sie die folgenden Tipps bei der An festlegen und beheben.

#WERT! Fehler

Tritt auf , wenn der für das Argument oder Spalten verwendete Wert unter der Gesamtzahl der Zeilen oder Spalten des Quellarrays geringer ist.

#N/A Fehler

Erscheint in gepolsterten Zellen, wenn das Argument pad_with nicht festgelegt ist.

#NAME? Fehler

Tritt auf, wenn entweder der Name der Funktion falsch geschrieben oder erweitert wird, ist in Ihrer Excel -Version nicht verfügbar. Derzeit wird es nur in Excel 365 und Excel für das Web unterstützt. Weitere Details finden Sie bei der Behebung des #NAME -Fehlers in Excel.

#VERSCHÜTTEN! Fehler

Tritt auf, wenn nicht genügend leere Zellen vorhanden sind, um das erweiterte Array auszugeben. In den meisten Situationen fixiert das Löschen der obstrudigen Zellen den Fehler gleichzeitig. Weitere Informationen finden Sie unter der Behebung von #spill! Fehler in Excel.

So verwenden Sie die Erweiterungsfunktion in Excel, um ein Array auf so viele Zeilen und Spalten zu erweitern, wie es für Ihre Geschäftslogik erforderlich ist. Ich danke Ihnen für das Lesen und hoffe, Sie nächste Woche in unserem Blog zu sehen!

Üben Sie die Arbeitsmappe zum Download

Excel Expect Formel - Beispiele (.xlsx -Datei)

Das obige ist der detaillierte Inhalt vonExcel -Erweiterungsfunktion, um das Array auf bestimmte Abmessungen zu erweitern. Für weitere Informationen folgen Sie bitte anderen verwandten Artikeln auf der PHP chinesischen Website!