Überprüfen Sie, ob der Wert in Reichweite in Excel und Google Sheets vorhanden ist

In diesem Artikel werden wir die am häufigsten verwendeten Formeln in Excel- und Google -Blättern untersuchen, um zu überprüfen, ob in einer Spalte, einer Reihe oder innerhalb eines Zellbereichs ein Wert vorhanden ist.

Unabhängig davon, ob Sie ein erfahrener Benutzer sind oder gerade erst anfangen, etwas über Ihr Lieblings -Tabellenkalkulationsprogramm zu erfahren, kann es viel Zeit und Mühe in Ihrer Datenanalyse sparen, wenn Sie schnell erkennen, ob ein bestimmter Wert vorhanden ist oder in einem bestimmten Bereich nicht vorhanden ist. Dies kann besonders nützlich sein, wenn sie mit großen Datensätzen arbeiten oder bei der Durchführung von Forschungen. In Microsoft Excel und Google Sheets gibt es verschiedene Formeln, um diese Aufgabe auszuführen. Mit unserer Schritt-für-Schritt-Anleitung können Sie sie problemlos auf Ihre Tabellenkalkulationen anwenden, unabhängig von der Struktur und Größe Ihres Datensatzes.

• Excel: Überprüfen Sie, ob der Wert im Bereich vorhanden ist
  • Wenn der Wert in der Spalte vorhanden ist
  • Wenn der Wert in Zeile auftritt
  • Wenn der Wert im Bereich erscheint
• Weitere Formeln, um den Suchwert in einem Bereich zu finden
• Google Sheets: Wenn der Wert im Bereich vorhanden ist
• Überprüfen Sie, ob der Wert in der Liste vorhanden ist - teilweise Übereinstimmung
• Markieren Sie Werte, die im Bereich vorhanden sind

Wenn der Wert im Bereich in Excel vorhanden ist

Um zu überprüfen, ob ein bestimmter Wert in einer Reihe von Zellen vorhanden ist und wenn dies der Fall ist, gibt es einen Text zurück, und wenn dies nicht der Fall ist, können Sie einen anderen Text zurückgeben, Sie können eine Kombination aus und countif -Funktionen verwenden.

If (countif ( Bereich , Wert )> 0, "Ja", "Nein")

In dieser Formel zählt Countif die Vorkommen eines bestimmten Werts in einem Bereich. Wenn die Anzahl größer als Null ist, gibt die Anweisung "Ja" zurück. Wenn der Wert nicht innerhalb des Bereichs gefunden wird, bringt die CountIF -Funktion Null und wenn Ausgänge "nein".

Diese generische Formel funktioniert gut in allen möglichen Szenarien.

Überprüfen Sie, ob der Wert in einer Spalte vorhanden ist

Um zu testen, ob ein Wert in C3 in Spalte A vorhanden ist (genauer gesagt im Bereich A3: A20), können Sie diese Formel verwenden:

=IF(COUNTIF($A$3:$A$20, C3)>0, "Yes", "No")

Bitte achten Sie darauf, dass wir die Range Referenz ($ A $ 3: $ a $ 20) sperren, indem wir das $ Sign für die Formel verwenden, um in den Zellen D4: D7 korrekt zu kopieren:

Überprüfen Sie, ob der Wert in einer Zeile vorhanden ist

Um herauszufinden, ob ein Wert in B5 in der Reihe B2: I2 erscheint, nimmt die Formel in dieser Form an:

=IF(COUNTIF($B$2:$I$2, B5)>0, "Yes", "No")

Überprüfen Sie, ob der Wert in einem Bereich vorhanden ist

Um zu überprüfen, ob ein bestimmter Wert in einem 2D -Bereich auftritt, liefern Sie den entsprechenden Bereich Referenz auf das erste Argument von CountIF. Zum Beispiel:

=IF(COUNTIF($A$3:$B$11, D3)>0, "Yes", "No")

Weitere Formeln, um den Suchwert in einem Bereich zu finden

Die IF -COUNTIF -Formel ist die einfachste, aber nicht die einzige Möglichkeit zu finden, wenn ein bestimmter Wert in einem Bereich erscheint. Im Folgenden finden Sie einige alternative Lösungen.

IsNumber und Match

Eine andere Möglichkeit, zu überprüfen, ob ein Wert in einer Liste auftritt, besteht darin, die Übereinstimmung zusammen mit der ISNumber -Funktion zu verwenden. Zum Beispiel:

=IF(ISNUMBER(MATCH(C3, $A$3:$A$20, 0)), "Yes", "No")

Die Match -Funktion gibt die Position des Suchwerts (C3) innerhalb des Bereichs (A3: A20) als Zahl zurück. ein #n/a -Fehler, wenn keine Übereinstimmung gefunden wird. Die ISNumber -Funktion wandelt eine Zahl in True und einen Fehler in False um. Wickeln Sie die Konstruktion in If "Ja" oder "Nein" als Endergebnis.

Isna und Vlookup

Eine etwas komplexere, aber immer noch funktionierende Lösung besteht darin, die IF- und Vlookup -Funktionen in einer Formel zu verwenden:

=IF(ISNA(VLOOKUP(C3, $A$3:$A$20, 1, FALSE)), "No", "Yes")

Hier ist die Vlookup -Funktion nach dem Suchwert das angegebene Array und gibt eine genaue Übereinstimmung (False) aus derselben Spalte (1) zurück. Wenn keine Übereinstimmung gefunden wird, wird ein #n/ein Fehler zurückgegeben. (In Excel 365 und Excel 2021 können Sie Xlookup anstelle von vlookup verwenden.) Die ISNA -Funktion überprüft das Ergebnis auf #N/A -Fehler und gibt true zurück, wenn sie positiv und ansonsten falsch sind. Schließlich gibt die IF -Funktion "Nein" für true (no Match) und "Ja" für false (Match) zurück.

Weitere Informationen finden Sie unter der Verwendung von ISNA mit Vlookup in Excel.

Isna und Match

Diese Lösung ist dem vorherigen sehr ähnlich, außer dass Sie Match anstelle von vlookup verwenden, um die Bereiche für Übereinstimmungen zu überprüfen:

=IF(ISNA(MATCH(C3, $A$3:$A$20, 0)), "No", "Yes")

Tipp. Wenn Sie das Ziel haben, einen Suchwert in einer Spalte zu finden und einen übereinstimmenden Wert aus einer anderen Spalte zurückzugeben, verwenden Sie die Funktion VLOOKUP oder XLOOKUP in seiner Grundform.

Wenn der Wert in Reichweite in Google Sheets besteht

In Google Sheets können Sie überprüfen, ob ein Wert in einem Bereich existiert, der genau dieselben Formeln verwendet, die wir in Excel verwendet haben.

Um beispielsweise festzustellen, ob der Wert in D3 im Bereich A3: B11 auftritt, lautet die Formel in E4:

=IF(COUNTIF($A$3:$B$11, D3)>0, "Yes", "No")

In unserer Beispiel -Tabelle finden Sie einige weitere Formeln, die am Ende dieses Tutorials verfügbar sind.

Überprüfen Sie, ob der Wert im Bereich vorhanden ist - teilweise Übereinstimmung

Um festzustellen, ob eine Zelle in einem Bereich ein bestimmtes Substring enthält, legen Sie einen Wildcard -Charakter (Asterisk) auf beiden Seiten des Suchwerts, damit Countif überall in einer Zelle danach sucht:

If (countif ( Bereich , " * Wert *")> 0, "Ja", "Nein")

Beispielsweise prüft die Bellow -Formel, ob eine Zelle im Bereich A3: B11 das Wort "Apfel" enthält:

=IF(COUNTIF(A3:B11, "*apple*")>0, "Yes", "No")

Wenn Sie sich auf eine bestimmte Zelle anstelle eines hartcodierten Werts beziehen, verkettet Sie Sternchen vor und nach der Zellreferenz wie folgt:

=IF(COUNTIF($A$3:$B$11,"*"&D3&"*")>0, "Yes", "No")

Markieren Sie Werte, die im Bereich existieren

Eine visuellere Möglichkeit, Werte zu identifizieren, die in einem bestimmten Bereich existieren, könnte darin bestehen, sie mit einer exzelbedingten Formatierung hervorzuheben. Die Schritte sind:

1. Wählen Sie die Zellen mit Werten aus, die Sie in einem Bereich finden möchten (C3: C7 in unserem Fall).
2. Klicken Sie auf der Registerkarte "Start" in der Styles -Gruppe auf Bedingte Formatierung> Neue Regel .
3. Wählen Sie im Fenster "Neue Formatierungsregel" Verwenden Sie eine Formel, um zu bestimmen, welche Zellen zu formatieren sind .
4. Geben Sie eine dieser Formeln in die Formatwerte ein, in denen diese Formel ein echtes Feld ist :

   =MATCH(C3, $A$3:$A$20, 0)

   =COUNTIF($A$3:$A$20, C3)>0

   Wobei C3 die oberste Zelle mit den Zielwerten ist und 3 USD $ 3: $ a $ 20 ist die Reichweite, die man überprüfen kann.

5. Klicken Sie auf das Format… Schaltfläche und konfigurieren Sie das gewünschte Formatieren.
6. Klicken Sie zweimal auf OK , um beide Dialogfenster zu schließen.

Erledigt! Alle Werte, die im Bereich (exakte Übereinstimmung) existieren, werden hervorgehoben:

Um die teilweise übereinstimmenden Werte hervorzuheben, ändern Sie die Formel, wie unten gezeigt - ein Sternchen auf beiden Seiten der Lookup -Wertreferenz verkettet:

=MATCH("*"&C3&"*", $A$3:$A$20, 0)

=COUNTIF($A$3:$A$20, "*"&C3&"*")>0

Tipp. Die gleiche Formel kann mit der bedingten Formatierung von Google Sheets verwendet werden, um genaue oder teilweise Übereinstimmungen in einem Bereich in Google -Tabellenkalkulationen hervorzuheben.

Jetzt sind Sie mit dem Wissen und den Fähigkeiten ausgestattet, um zu überprüfen, ob ein Wert in einer Spalte, Reihen oder Reichweite mit Vertrauen und Leichtigkeit vorhanden ist. Danke fürs Lesen!

Üben Sie Arbeitsbücher

Überprüfen Sie, ob der Wert in Reichweite in Excel (.xlsx -Datei) vorhanden ist, wenn der Wert in Reichweite in Google Sheets (Online -Blatt) vorhanden ist.

Das obige ist der detaillierte Inhalt vonÜberprüfen Sie, ob der Wert in Reichweite in Excel und Google Sheets vorhanden ist. Für weitere Informationen folgen Sie bitte anderen verwandten Artikeln auf der PHP chinesischen Website!