Excel ChooseRows Fonction pour extraire certaines lignes du tableau

Dans ce tutoriel, nous allons examiner en profondeur la fonction Excel 365 nommée Chooserows et ses utilisations pratiques.

Supposons que vous ayez une feuille de calcul Excel avec des centaines de lignes à partir desquelles vous souhaitez en extraire des lignes spécifiques, par exemple, toutes les lignes étranges ou même, les 5 premières ou les 10 dernières lignes, etc. Vous sentez-vous déjà ennuyé à l'idée de copier et de coller les données manuellement ou d'écrire un code VBA pour automatiser la tâche? Ne t'inquiète pas! Tout est beaucoup plus simple qu'il n'y paraît. Utilisez simplement la nouvelle fonction Dynamic Array ChooseRows.

• Fonction excel chooserows
• Comment utiliser la fonction de chooserows dans Excel
• Retourner les n lignes N du tableau
• Extraire toutes les autres lignes
• Flip Array Verticalement
• Extraire les lignes de plusieurs tableaux
• Obtenez des lignes en fonction de la chaîne avec des numéros
• La fonction Excel Chooserows ne fonctionne pas

Fonction excel chooserows

La fonction Chooserows dans Excel est utilisée pour extraire les lignes spécifiées d'un tableau ou d'une plage.

La syntaxe est la suivante:

Chooserows (Array, ROW_NUM1, [ROW_NUM2],…)

Où:

Tableau (requis) - le tableau source.

Row_num1 (requis) - un entier représentant l'indice numérique de la première ligne à retourner.

ROW_NUM2 ,… (Facultatif) - Nombres d'index des lignes supplémentaires à retourner.

Voici comment fonctionne la fonction Chooserows dans Excel 365:

Disponibilité de la fonction de chooserows

La fonction ChOOSEROWS est uniquement disponible dans Excel pour Microsoft 365 (Windows et Mac) et Excel pour le Web.

Conseil. Pour obtenir certaines colonnes à partir d'une gamme ou d'un tableau, utilisez la fonction ChooseCols.

Comment utiliser la fonction de chooserows dans Excel

Pour tirer des lignes particulières d'un tableau donné, construisez une formule ChooseRows de cette manière:

1. Pour le tableau , vous pouvez fournir une gamme de cellules ou un tableau de valeurs entraînées par une autre formule.
2. Pour ROW_NUM , fournissez un entier positif ou négatif indiquant la ligne à retourner. Un nombre positif récupère une ligne correspondante à partir du début du tableau, un nombre négatif - à partir de la fin du tableau. Les numéros de lignes multiples peuvent être fournis individuellement dans des arguments distincts ou dans un argument sous la forme d'une constante de tableau.

En tant que fonction de tableau dynamique Excel, ChooseRows gère les tableaux nativement. Vous entrez la formule dans la cellule supérieure gauche de la plage de destination, et il se déverse automatiquement dans autant de colonnes et de lignes que nécessaire. Le résultat est un réseau dynamique unique, également connu sous le nom de plage de déversement.

Par exemple, pour obtenir les lignes 2, 4, 6, 8 et 10 de la plage A4: D13, la formule est:

=CHOOSEROWS(A4:D13, 2, 4, 6, 8, 10)

Alternativement, vous pouvez utiliser une constante de tableau telle que {2,4,6,8,10} ou {2; 4; 6; 8; 10} pour spécifier les lignes souhaitées:

=CHOOSEROWS(A4:D13, {2,4,6,8,10})

Ou

=CHOOSEROWS(A4:D13, {2;4;6;8;10})

Une autre façon de fournir les nombres de lignes est de les entrer dans des cellules distinctes, puis à l'aide des références de cellules individuelles pour plusieurs arguments ROW_NUM ou une référence de plage pour un argument ROW_NUM unique.

Par exemple:

=CHOOSEROWS(A4:D13, F4, G4, H4)

=CHOOSEROWS(A4:D13, F4:H4)

Un avantage de cette approche est qu'il vous permet d'extraire d'autres lignes en modifiant simplement les nombres dans les cellules prédéfinies sans modifier la formule elle-même.

Ci-dessous, nous discuterons de quelques autres exemples de formule Chooserows pour gérer des cas d'utilisation plus spécifiques.

Retourner les lignes de la fin d'un tableau

Pour obtenir rapidement les n lignes N dernière d'une plage, fournissez des nombres négatifs pour les arguments ROW_NUM . Cela obligera la fonction à compter les lignes de la fin du tableau.

Par exemple, pour obtenir la dernière ligne de la plage A4: D13, utilisez cette formule:

=CHOOSEROWS(A4:D13, -3, -2, -1)

Le résultat sera un tableau à 3 rangées où les lignes apparaissent dans le même ordre que dans la plage référée.

Pour retourner les 3 dernières lignes dans l'ordre inverse, du bas en haut, modifiez l'ordre des arguments ROW_NUM comme ceci:

=CHOOSEROWS(A4:D13, -1, -2, -3)

Extraire toutes les autres lignes d'un tableau dans Excel

Pour obtenir toutes les autres lignes à partir d'une plage donnée, utilisez ChooseRows en combinaison avec quelques autres fonctions. La formule variera légèrement selon que vous extrairez les lignes étranges ou même.

Pour retourner des lignes étranges telles que 1, 3, 5,… la formule prend cette forme:

=CHOOSEROWS(A4:D13, SEQUENCE(ROUNDUP(ROWS(A4:D13)/2, 0), 1, 1, 2))

Pour retourner même des lignes telles que 2, 4, 6,… La formule se déroule comme suit:

=CHOOSEROWS(A4:D13, SEQUENCE(ROUNDDOWN(ROWS(A4:D13)/2, 0), 1, 2, 2))

Comment fonctionne cette formule:

Essentiellement, la fonction Chooserows renvoie les lignes basées sur un tableau de nombres ODD ou même séquentiels générés par la fonction de séquence. Une rupture de formule détaillée suit ci-dessous.

Tout d'abord, vous déterminez le nombre de lignes à retourner. Pour cela, vous utilisez la fonction des lignes pour obtenir le nombre total de lignes dans le tableau référencé, que vous divisez par 2, puis tournez le quotient vers le haut ou vers le bas vers l'entier à l'aide d'un tour d'horizon ou d'un arrondissement. Comme ce nombre sera ultérieur à l'argument de séquence des lignes , l'arrondi est nécessaire pour obtenir un entier au cas où la plage de source contient un nombre impair de lignes.

Comme notre gamme de source a un nombre uniforme de lignes (10) qui est exactement divisée par 2, les deux Roundup (10/2, 0) et le rond (10/2, 0) renvoient le même résultat, qui est 5.

Le numéro retourné est servi à la fonction de séquence.

Pour les lignes étranges:

SEQUENCE(5, 1, 1, 2)

Pour même les lignes:

SEQUENCE(5, 1, 2, 2)

La formule de séquence ci-dessus produit un tableau de nombres composés de 5 lignes et 1 colonne, à partir de 1 pour les lignes impairs (à 2 pour même les lignes), et incrémentée par 2.

Pour les lignes étranges, nous obtenons ce tableau:

{1;3;5;7;9}

Pour même les lignes, nous obtenons celui-ci:

{2;4;6;8;10}

Le tableau généré va à l'argument ROW_NUM1 de ChooseRows, et vous obtenez le résultat souhaité:

=CHOOSEROWS(A4:D13, {1;3;5;7;9})

Inverser l'ordre des lignes dans un tableau

Pour retourner un tableau verticalement de haut en bas, vous pouvez également utiliser les fonctions de chooserows et de séquence ensemble. Par exemple:

=CHOOSEROWS(A4:D13, SEQUENCE(ROWS(A4:D13))*-1)

Dans cette formule, nous ne définissons que le premier argument ( lignes ) de séquence, ce qui équivaut au nombre total de lignes dans les lignes de tableau initiales (A4: D13). Les arguments omis ( colonnes , démarrage , étape ) par défaut 1. En conséquence, la séquence produit un tableau de nombres séquentiels tels que 1, 2, 3,…, n, où n est la dernière ligne dans le tableau source. Pour faire en sorte que ChoOserows compte les lignes dans la direction de la baisse, la séquence générée est multipliée par -1, de sorte que l'argument ROW_NUM obtient un tableau de nombres négatifs tels que {-1; -2; -3; -4; -5; -6; -7; -8; -9; -10}.

En conséquence, l'ordre des éléments de chaque colonne est modifié de haut en bas:

Extraire les lignes de plusieurs tableaux

Pour obtenir des lignes spécifiques à partir de deux plages non contiguës ou plus, vous les combinez d'abord à l'aide de la fonction VSTACK, puis transmettez la plage fusionnée à ChooseRows.

Par exemple, pour extraire les deux premières lignes de la plage A4: D8 et les deux dernières lignes de la plage A12: D16, utilisez cette formule:

=CHOOSEROWS(VSTACK(A4:D8, A12:D16), 1, 2, -2, -1)

Obtenez des lignes en fonction d'une chaîne contenant des numéros de ligne

Cet exemple montre comment renvoyer des lignes particulières en extraitant les nombres d'une chaîne alpha-nucléaire.

Supposons que vous ayez des chiffres séparés par des virgules dans Cell G3 répertoriant les rangées d'intérêt. Pour extraire les numéros de ligne à partir d'une chaîne, utilisez la fonction textSplit qui peut diviser une chaîne de texte par un délimiteur donné (virgule dans notre cas):

=TEXTSPLIT(G3, ",")

Le résultat est un tableau de valeurs de texte telles que {"3", "5", "7", "10"}. Pour le convertir en un tableau de nombres, effectuez une opération mathématique qui ne modifie pas les valeurs, disons 0 ou * 1.

=TEXTSPLIT(G3, ",") *1

Cela produit la constante de tableau numérique {3,5,7,10} dont la fonction Chooserows a besoin, vous intégrez donc la formule TextsPlit dans l'argument 2 ^nd :

=CHOOSEROWS(A4:D13, TEXTSPLIT(G3, ",") *1)

En conséquence, toutes les lignes spécifiées sont renvoyées en tant que tableau unique:

La fonction de chooserows ne fonctionne pas

Si la formule Chooserows entraîne une erreur, il est très probable que ce soit l'une de ces raisons.

#VALEUR! erreur

Se produit si la valeur absolue de tout argument ROW_NUM est nulle ou supérieure au nombre total de lignes dans le tableau.

#NOM? erreur

Se produit si le nom de la fonction est mal orthographié ou si la fonction n'est pas prise en charge dans votre Excel. Actuellement, ChOOSEROWS n'est disponible que dans Excel 365 et Excel pour le Web. Pour plus de détails, lisez comment corriger l'erreur #Name dans Excel.

#RÉPANDRE! erreur

Se produit lorsqu'il n'y a pas assez de cellules vierges pour se remplir avec les résultats. Pour le réparer, effacez simplement les cellules obstruées. Pour plus d'informations, veuillez consulter Excel #spill! erreur.

C'est comment utiliser la fonction ChooseRows dans Excel pour retourner des lignes particulières à partir d'une gamme ou d'un tableau. Merci d'avoir lu et j'espère vous voir sur notre blog la semaine prochaine!

Classeur de pratique pour télécharger

Formule Excel ChOOSEROWS - Exemples (fichier .xlsx)

Ce qui précède est le contenu détaillé de. pour plus d'informations, suivez d'autres articles connexes sur le site Web de PHP en chinois!