Excel élargir la fonction pour étendre le tableau aux dimensions spécifiées

Le tutoriel présente une nouvelle fonction de tableau dynamique Excel 365 qui peut étendre un tableau aux dimensions souhaitées avec une valeur de votre choix.

Vous voulez augmenter un tableau sur un nombre spécifié de lignes ou de colonnes afin que tous les tableaux similaires de votre feuille de calcul aient la même taille? Dans Excel 365, cela peut être fait avec une formule simple. Rencontrez la toute nouvelle fonction Expand qui peut développer un tableau à toutes les dimensions que vous définissez.

• Excel Expand Fonction
• Comment utiliser la fonction d'extension dans Excel
• Étendre le tableau à un nombre donné de lignes
• Étendre le tableau à un nombre donné de colonnes
• Développer un tableau laissé et plus
• Tableau de chaîne et de pad
• Excel élargir la fonction ne fonctionne pas

Excel Expand Fonction

La fonction d'extension dans Excel est conçue pour remplir un tableau avec une valeur de votre choix aux dimensions de ligne et de colonne spécifiées.

La syntaxe comprend les arguments suivants:

Développer (array, lignes, [colonnes], [pad_with])

Où:

Tableau (requis) - le tableau d'origine.

Rows (facultatif) - Le nombre de lignes dans le tableau renvoyé. S'il est omis, de nouvelles lignes ne sont pas ajoutées et l'argument des colonnes doit être défini.

Colonnes (Facultatif) - Le nombre de colonnes dans le tableau renvoyé. S'il est omis, de nouvelles colonnes ne sont pas ajoutées et l'argument des lignes doit être défini.

PAD_WITH - La valeur pour remplir de nouvelles cellules avec. S'il est omis, par défaut # n / a.

Conseil. Pour supprimer les lignes ou les colonnes indésirables d'un tableau, utilisez la fonction de dépôt.

Développer la disponibilité de la fonction

Actuellement, la fonction Expand est disponible dans Excel pour Microsoft 365 (Windows et Mac) et Excel pour le Web.

Comment utiliser la fonction d'extension dans Excel

Pour augmenter un tableau à la taille souhaitée, construisez une formule d'extension de cette manière:

1. Pour le tableau , fournissez une gamme de cellules ou un tableau de valeurs renvoyées par une autre formule.
2. Pour les lignes et les colonnes , fournissez des nombres positifs supérieurs au nombre de lignes et de colonnes dans le tableau d'origine. Notez que ces arguments définissent les dimensions du tableau résultant , et non le nombre de lignes ou de colonnes à ajouter. Dans chaque formule particulière, les lignes ou les colonnes doivent être définies. L'argument omis par défaut est la dimension correspondante (lignes ou colonnes) du tableau source.
3. Pour PAD_WITH , spécifiez la valeur pour remplir les nouvelles cellules ajoutées au tableau. S'il s'agit d'une valeur de texte, enfermez-la en doubles guillemets. S'il s'agit d'une valeur numérique, utilisez-le sans guillemets. S'il n'est pas fourni, les nouvelles cellules seront rembourrées avec l'erreur # N / A.

Étant une fonction de tableau dynamique, l'extension ne doit être saisie que dans une seule cellule, et il renverse automatiquement les résultats en autant de cellules que spécifiées dans les arguments des lignes et des colonnes .

Par exemple, pour étendre le tableau C6: D13 à 12 lignes et 3 colonnes, la formule est:

=EXPAND(C6:D13, 12, 3)

Comme l'argument PAD_WITH n'est pas défini, la formule ci-dessus remplira les cellules nouvellement ajoutées avec l'erreur # n / a. Pour modifier le comportement par défaut, fournissez toute valeur que vous souhaitez pour l'argument PAD_WITH . Par exemple, vous pouvez remplir les nouvelles valeurs de tableau avec un trait d'union:

=EXPAND(C6:D13, 12, 3, "-")

Ci-dessous, vous trouverez quelques autres exemples d'utilisation de la fonction d'extension dans Excel pour développer un tableau dans une direction spécifique.

Développez le tableau à un certain nombre de lignes

Pour étendre un tableau jusqu'au nombre de lignes souhaité, définissez l'argument des lignes et omettez les colonnes .

Par exemple, pour augmenter le tableau initial à un total de 12 lignes, utilisez cette formule:

=EXPAND(C6:D13, 12, , "-")

Étant donné que les colonnes ne doivent pas être étendues, nous tapons une virgule après les lignes et après la virgule, entrez la valeur de rembourrage.

Développez le tableau à un certain nombre de colonnes

Pour ajouter plus de colonnes à un tableau, définissez l'argument des colonnes et omettez les lignes .

Par exemple, voici comment vous pouvez étendre le tableau source à droite, il a donc un total de 4 colonnes:

=EXPAND(A4:C15, , 4, "-")

Comment développer un tableau laissé et plus

La fonction d'extension est conçue pour étendre un tableau à droite et à la baisse. Pour ajouter des cellules à gauche et au-dessus du réseau source, vous devrez élaborer votre propre solution.

Supposons que vous ayez un tableau de valeurs en B4: C12. Vous visez à ajouter 3 lignes au-dessus et 1 colonne à gauche du tableau d'origine. Pour mieux comprendre la mécanique, nous effectuerons d'abord chaque tâche individuellement, puis assembler toutes les pièces.

Ajouter des colonnes à gauche

Pour étendre le tableau horizontalement, vous pouvez utiliser la fonction HSTACK pour ajouter un nombre donné de colonnes vides à gauche de votre tableau. Dans cet exemple, nous ajoutons 1 colonne vierge en utilisant cette formule:

=HSTACK(D4:D12, B4:C12)

Notez qu'un tableau vide que vous empilez (D4: D12) doit avoir le même nombre de lignes que le tableau source et doit être fourni en premier dans la formule. En conséquence, une colonne de valeurs zéro est ajoutée à gauche du tableau d'origine.

Ajouter des lignes au-dessus

Pour étendre le tableau verticalement, tirez parti de la fonction VSTACK pour placer un certain nombre de lignes vides au-dessus de la première ligne de votre tableau d'origine.

Dans notre cas, les deux gammes suivantes avec le même nombre de colonnes sont empilées, un tableau vide venant en premier:

=VSTACK(B14:C16, B4:C12)

Dans le résultat, 3 lignes avec des valeurs nulles sont ajoutées en haut du tableau initial.

Ajouter des lignes au-dessus et des colonnes à gauche

Pour étendre un tableau verticalement et horizontalement, nidine la fonction VStack et Hstack dans l'autre. Dans notre cas, la formule prend cette forme:

=VSTACK(B14:D16, HSTACK(D4:D12, B4:C12))

Et produit ce résultat:

Taper un tableau et laisser avec une valeur personnalisée

Par défaut, les fonctions VSTACK et HSTACK renvoient les zéros au lieu de cellules vierges. Pour remplir les nouvelles cellules avec une valeur personnalisée, nidine une combinaison de IF et Isblank dans chaque fonction de pile, qui remplacera les blancs par la valeur que vous spécifiez.

Par exemple, pour que les nouvelles cellules soient rembourrées avec un trait d'union, la formule est:

=VSTACK(IF(ISBLANK(B14:D16),"-", B14:D16), HSTACK(IF(ISBLANK(D4:D12),"-", D4:D12), B4:C12))

Pour étendre un tableau avec des cellules vierges, utilisez cette formule:

=VSTACK(IF(ISBLANK(B14:D16),"", B14:D16), HSTACK(IF(ISBLANK(D4:D12),"", D4:D12), B4:C12))

Clissons divisés et élargir les tableaux

Cet exemple montre comment utiliser les fonctions EXPAND et TextsPlit pour diviser une chaîne de texte par un délimiteur spécifique dans des colonnes individuelles, puis développer le tableau final à la taille souhaitée.

Disons que vous avez une colonne de chaînes comme la colonne B dans l'image ci-dessous. Chaque chaîne a plusieurs valeurs séparées avec un délimiteur particulier (une virgule et un espace dans notre cas). Votre objectif est de diviser chaque chaîne en cellules distinctes, de sorte que tous les tableaux résultants ont le même nombre de colonnes.

Pour accomplir la tâche, entrez cette formule dans E4:

=EXPAND(TEXTSPLIT(B4, ", "), , COLUMNS(E3:H3), "-")

Dans cette formule:

• Textsplit sépare les valeurs en B4 à l'aide d'une virgule et d'un espace (",") comme délimiteur.
• Les colonnes calculent le nombre de colonnes dans le tableau de sortie.
• Extension étend le tableau renvoyé aux valeurs manquantes de rembourrage droit avec des traits de traits ("-").

Faites glisser la formule vers le bas sur E15 et vous obtiendrez ce résultat:

Développez la fonction ne fonctionne pas

Si la fonction d'extension fonctionne de manière incorrecte dans votre Excel ou lance une erreur, les conseils suivants vous aideront à épingler la cause et à le réparer.

#VALEUR! erreur

Se produit si la valeur utilisée pour l'argument des lignes ou des colonnes est inférieure au nombre total de lignes ou de colonnes du tableau source.

# N / une erreur

Apparaît dans les cellules rembourrées si l'argument PAD_WITH n'est pas défini.

#NOM? erreur

Se produit si le nom de la fonction est mal orthographié ou si l'extension n'est pas disponible dans votre version Excel. Actuellement, il n'est pris en charge que dans Excel 365 et Excel pour le Web. Plus de détails peuvent être trouvés pour fixer l'erreur #Name dans Excel.

#RÉPANDRE! erreur

Se produit lorsqu'il n'y a pas suffisamment de cellules vides pour sortir le tableau étendu. Dans la plupart des situations, la compensation des cellules obstruées corrige l'erreur à la fois. Pour plus d'informations, veuillez voir comment réparer #Spill! Erreur dans Excel.

C'est comment utiliser la fonction Expand dans Excel pour étendre un tableau à autant de lignes et de colonnes que le besoin de votre logique métier. Je vous remercie d'avoir lu et j'espère vous voir sur notre blog la semaine prochaine!

Classeur de pratique pour télécharger

Excel élargir la formule - Exemples (fichier .xlsx)

Ce qui précède est le contenu détaillé de. pour plus d'informations, suivez d'autres articles connexes sur le site Web de PHP en chinois!