ExcelとGoogleシートのケースに敏感なSumifとSumif

このチュートリアルでは、ExcelおよびGoogleシートでケースに敏感なSumifまたはSumifs式を作成する方法を学びます。

Microsoft ExcelとGoogleシートの両方で、SumifとSumifの関数が利用できます。また、両方のアプリケーションでは、本質的にケースに依存しません。小文字と大文字を異なる文字として扱う細胞を条件付きで合計するには、何か他のものを考え出す必要があります。

• Sumif Caseは敏感ですか？
• Excel：ケースに敏感な場合は合計します
• Excel：sum ifs case-sensitive（複数の基準）
• Excel：CELLに症例に敏感な場合の合計
• Googleシート：ケースに敏感なSumif
• Googleシート：ケースに敏感なSumif（複数の基準）

Sumif / Sumifsケースは敏感ですか？

いいえ、そうではありません。 ExcelとGoogleの両方のシートで、SumifもSumifも文字ケースを認識することはできません。これを確認するには、この簡単な例を考慮してください。

列AにIDのリストがあると仮定します。ここでは、大文字と小文字が異なるアイテムを示しています。対応する販売数値は列Bにあります。目標は、特定のアイテム、たとえばA-01の販売の合計を取得することです。

E1のターゲットIDを使用すると、この古典的なSumif式を作成します。

=SUMIF(A2:A6, E1, B2:B6)

そして、絶対に間違った結果を得る:(

Excelの式の場合のケースに敏感な合計

文字ケースを考慮して1つの条件でセルを合計するには、統合機能と正確な機能を一緒に使用できます。

sunproduct（ - （exact（ criteria 、 range ））、 sum_range ）

E1（基準）のターゲットID、A2：A10（範囲）のアイテムリスト、およびB2：B10（ SUM_RANGE ）の販売番号を使用すると、式は次の形式を取得します。

=SUMPRODUCT(--(EXACT(E1, A2:A10)), B2:B10)

必要に応じて、式の基準を直接「ハードコード」できます。

=SUMPRODUCT(--(EXACT("A-01", A2:A10)), B2:B10)

この式の仕組み：

フォーミュラの中心にある正確な関数は、ターゲットアイテム（E1）をリスト内の各アイテムと比較し、比較値がテキストケースを含めてまったく同じである場合にtrueを返します。

{TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;TRUE;FALSE;FALSE}

二重統一オペレーター（ - ）は、それぞれ真と偽を1と0に変換します。

{1;0;0;0;1;0;1;0;0}

等式関数は、上記のアレイの要素にB2：B10の対応するアイテムを掛けます：

SUMPRODUCT({1;0;0;0;1;0;1;0;0}, {250;155;130;255;160;280;170;285;110})

そして、0を乗算するとゼロが得られるため、正確に返された真の項目のみが生き残ります。

SUMPRODUCT({250;0;0;0;160;0;170;0;0})

最後に、Sumproductは製品を合計し、合計を出力します。

Excelのケースに敏感な合計IFS（複数の基準を持つ）

2つ以上の基準を持つケースに敏感なSumif式を探している場合は、別の正確な関数で追加の範囲/基準ペアを定義することでこの動作をエミュレートできます。

sumproduct（ - （exact（ criteria1 、 range1 ））、 - （exact（ criteria2 、 range2 ））、 sum_range ））

たとえば、特定の領域（F1）の特定のアイテム（F1）の売上を合計するために、式は次のとおりです。

=SUMPRODUCT(--(EXACT(F1, A2:A10)), --(EXACT(F2, B2:B10)), C2:C10)

ケースに敏感な「セルが含まれている場合の合計」Excelの式

別の列のセルにセルのコンテンツの一部として特定のテキストが含まれている場合、1つの列に値を合計する必要がある状況では、検索と一緒に等式関数を使用します。

sumproduct（ - （isNumber（find（ criteria 、 range ）））、 sum_range ）

たとえば、E1（A2：A10のセル全体と一致するか、テキスト文字列の一部になることができる）のアイテムの販売を合計するには、次の式は次のとおりです。

=SUMPRODUCT(--(ISNUMBER(FIND(E1, A2:A10))), B2:B10)

複数の条件に基づいてセルを合計するには、もう1つのISNumber/Findコンボを追加します。

sumproduct（ - （isNumber（find（ criteria1 、 range1 ）））、 - （isNumber（find（ criteria2 、 range2 ）））、 sum_range ）

たとえば、2つの条件（F1のアイテムIDとF2の領域）で販売の合計を取得するには、式は次のとおりです。

=SUMPRODUCT(--(ISNUMBER(FIND(F1, A2:A10))), --(ISNUMBER(FIND(F2, B2:B10))), C2:C10)

このフォーミュラは、北、北東、北西などの「北」地域で指定されたアイテムの販売を合計することに注意してください。

この式の仕組み：

ここでは、ターゲットアイテム（E1）を検索するために、ケースに敏感な検索関数を使用します。アイテムが見つかると、関数はソース文字列の相対位置を返します。それ以外の場合は#valueエラーです。

{2;#VALUE!;#VALUE!;#VALUE!;1;#VALUE!;1;#VALUE!;#VALUE!}

ISNumber関数は任意の数値を真の数に変換し、エラー値をfalseに変換します。

{TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;TRUE;FALSE;FALSE}

次に、「二重否定」（ - ）を行い、論理値を1と0に強制します。

{1;0;0;0;1;0;1;0;0}

最後に、sumproduct関数は2つの配列の要素を掛け、結果を出力します。

SUMPRODUCT({1;0;0;0;1;0;1;0;0}, {250;155;130;255;160;280;170;285;110})

フォーミュラが複数の条件を処理する場合、supproductは3つ以上の配列の要素を掛けます。私たちの場合、それは次のとおりです。

=SUMPRODUCT({1;0;0;0;1;0;1;0;0}, {1;0;1;1;1;1;0;1;0}, {250;155;130;255;160;280;170;285;110})

GoogleシートにはSumif Case-Sensitive

Excel用に構築した式がGoogleシートでも機能する場合、ケースに敏感な合計。さらに、GoogleシートのSUMIF関数自体を取得して、大文字と小文字の文字を区別できます。方法は次のとおりです。

sumif（arrayformula（exact（ criterion 、 range ））、true、 sum_range ）

または

sumif（arrayformula（find（ criterion 、 range ））、1、 sum_range ）

サンプルデータセットの場合、実際の式は次のように見えます。

=SUMIF(ArrayFormula(EXACT(E1, A2:A10)), TRUE, B2:B10)

=SUMIF(ArrayFormula(FIND(E1, A2:A10)), 1, B2:B10)

Sumif/正確な式の仕組み：

GoogleシートのSumif（範囲、Criterion、[sum_range]）関数を作成するには、文字ケースを認識します。範囲の引数に次の式を使用します。

ArrayFormula(EXACT(E1, A2:A10))

Arrayformulaは、A2：A10の各値とE1の値を比較することを正確に強制します。正確な一致が見つかった場合、フォーミュラはtrueを返します。

真の値と偽の値の範囲では、Sumifは真の値を検索し、B2：B10の対応する値を加算します。それだけです！

sumif/find式の仕組み：

ここでは、Arrayformulaの組み合わせを使用して、範囲A2：A10でターゲット値（E1）を探すために検索します。

ArrayFormula(FIND(E1, A2:A10))

別々に使用すると、FIND関数は最初の一致を見つけた後に検索を停止します。

ターゲット値が見つかっていても、式は1（検索文字列の相対位置です）を返します。値が見つからないセルの場合、#value！エラーが返されます。

次に、ナンバー1をSumifの基準として使用し、仕事を完了させます:)

Googleシートではsumifs case-sensitive

Googleシートに複数の条件を持つセルを要約するには、Excelのチュートリアルの一部で説明されているケースに敏感な概要式式またはGoogleシートのSumifを正確に組み合わせて使用​​するか、検索することができます。

sumifs（ sum_range 、arrayformula（exact（ criterion1 、 range1 ））、true、arrayformula（exact（ criterion2 、 range2 ））、true）

または

sumifs（ sum_range 、arrayformula（find（ criterion1 、 range1 ））、1、arrayformula（find（ criterion2 、 range2 ））、1）

ご覧のとおり、ロジックはsumif関数と同じです。違いは、2つ以上の範囲/基準ペアを使用することです。

たとえば、F1のアイテムとF2の領域の販売を合計するには、式は次のとおりです。

=SUMIFS(C2:C10, ArrayFormula(EXACT(F1, A2:A10)), TRUE, ArrayFormula(EXACT(F2, B2:B10)), TRUE)

=SUMIFS(C2:C10, ArrayFormula(FIND(F1, A2:A10)), 1, ArrayFormula(FIND(F2, B2:B10)), 1)

これは、ExcelおよびGoogleシートでケースに敏感なSumifまたはSumifの式を作成する方法です。お読みいただきありがとうございます。来週のブログでお会いしましょう！

ワークブックを練習します

Excel（.xlsxファイル）のケースに敏感なsumif / sumifs（Googleシート）のケース感受性Sumif / sumif / sumifs（オンラインシート）

以上がExcelとGoogleシートのケースに敏感なSumifとSumifの詳細内容です。詳細については、PHP 中国語 Web サイトの他の関連記事を参照してください。