Linuxのcmdファイルとは何ですか-よくある問題-php.cn

Linux では、cmd ファイルはリンカーの構成情報を保存し、コマンドファイルとして参照できるリンクコマンドファイルです。cmd ファイルの機能は、プログラムのリンク方法を示すことです。。 cmd ファイルは、MEMORY と SECTIONS の 2 つの部分で構成されます。MEMERY は、各メモリブロックの名前、開始アドレス、長さを定義するために使用され、SECTIONS は主に、どのセグメントが記憶領域のどのセグメントにマップされるかを記述するために使用されます。

Linuxのcmdファイルとは何ですか

#このチュートリアルの動作環境: linux7.3 システム、Dell G3 コンピューター。

cmd ファイルとは何ですか?

cmd ファイルは、接尾辞 .cmd で終わるリンカコマンドファイル (リンカコマンドファイル) です。

CMD の正式名称は、リンカの設定情報を格納するリンカ設定ファイルで、略してコマンドファイルと呼びます。名前からわかるように、このファイルの目的は、プログラムのリンク方法を指定することです。

TI DSP プログラムを作成する場合、プログラムはテキスト、bss などの多くのセグメントに分割でき、各セグメントには異なる役割があることがわかります。映画の中で実際に走る場合は、場所も異なります。たとえば、テキストコードは通常フラッシュに配置する必要がありますが、bss 変数は RAM に配置する必要があります。等しかし、チップが異なれば各メモリの開始アドレスと終了アドレスも異なるため、リンカはユーザーが特定のセクション、特にカスタムセクションをどのメモリのどこに配置したいのかを知りません。使用するチップの内部記憶領域の割り当てと、プログラムの各セクションの具体的な記憶場所をリンカに伝えるために、構成ファイル、つまり CMD ファイルを記述する必要があります。

cmd ファイルは、MEMORY (つまり、メモリ) と SECTIONS (つまり、セグメント) の 2 つの部分で構成されます。 MEMERY は、各メモリブロックの名前、開始アドレス、長さを定義するために使用されます。 SECTIONS は主に、どのセグメントが記憶領域のどのセグメントにマップされるかを記述するために使用されます。 MEMORYは、PAGE0（プログラム記憶領域）とPAGE1（データ記憶領域）、PAGE（つまり、フレーム）に分割できます。

上記のセグメントは、初期化されたセグメントと初期化されていないセグメントの 2 つのカテゴリに分類できます。初期化されたセグメントには実際の命令とデータが含まれており、プログラムメモリ空間に保存されます。未初期化セグメントは、変数のアドレス空間を予約するだけです。未初期化セグメントには実際の内容はありません。データは、プログラムの実行中に変数に書き込まれ、データ記憶域に格納されます。 C言語には、「.text」、「.const」、「.system」など、定義されたセグメントが多数あります。これらの定義されたセグメントについては、インターネット上に多くの説明があるため、ここでは詳しく説明しません。この記事では次に、ユーザーとしてセグメントを定義する方法を読者に紹介します。

MEMORY と SECTION

cmd ファイル内にコメントを「/*」と「*/」で囲んで記述できますが、「//」は許可されません」という点がC言語とは異なります。

cmd ファイルを作成するには、2 つの疑似命令 MEMORY と SECTIONS (大文字にする必要があります) を使用する必要があります。

MEMORY と SECTION の構文はオンラインで公開されていますので、この記事では MEMORY と SECTION の内容を具体例を交えて説明します。

作者が使用しているF28335のcmdファイルを元にMEMORYを説明します。

MEMORY
{
PAGE 0:    /* Program Memory */
           /* Memory (RAM/FLASH/OTP) blocks can be moved to PAGE1 for data allocation */
 
   ZONE0       : origin = 0x004000, length = 0x001000     /* XINTF zone 0 */
   RAML0       : origin = 0x008000, length = 0x001000     /* on-chip RAM block L0 */
   RAML1       : origin = 0x009000, length = 0x001000     /* on-chip RAM block L1 */
   RAML2       : origin = 0x00A000, length = 0x001000     /* on-chip RAM block L2 */
   RAML3       : origin = 0x00B000, length = 0x001000     /* on-chip RAM block L3 */
   ZONE6       : origin = 0x0100000, length = 0x100000    /* XINTF zone 6 */ 
   ZONE7A      : origin = 0x0200000, length = 0x00FC00    /* XINTF zone 7 - program space */ 
   FLASHH      : origin = 0x300000, length = 0x008000     /* on-chip FLASH */
   FLASHG      : origin = 0x308000, length = 0x008000     /* on-chip FLASH */
   FLASHF      : origin = 0x310000, length = 0x008000     /* on-chip FLASH */
   FLASHE      : origin = 0x318000, length = 0x008000     /* on-chip FLASH */
   FLASHD      : origin = 0x320000, length = 0x008000     /* on-chip FLASH */
   FLASHC      : origin = 0x328000, length = 0x008000     /* on-chip FLASH */
   FLASHA      : origin = 0x338000, length = 0x007F80     /* on-chip FLASH */
   CSM_RSVD    : origin = 0x33FF80, length = 0x000076     /* Part of FLASHA.  Program with all 0x0000 when CSM is in use. */
   BEGIN       : origin = 0x33FFF6, length = 0x000002     /* Part of FLASHA.  Used for "boot to Flash" bootloader mode. */
   CSM_PWL     : origin = 0x33FFF8, length = 0x000008     /* Part of FLASHA.  CSM password locations in FLASHA */
   OTP         : origin = 0x380400, length = 0x000400     /* on-chip OTP */
   ADC_CAL     : origin = 0x380080, length = 0x000009     /* ADC_cal function in Reserved memory */
   
   IQTABLES    : origin = 0x3FE000, length = 0x000b50     /* IQ Math Tables in Boot ROM */
   IQTABLES2   : origin = 0x3FEB50, length = 0x00008c     /* IQ Math Tables in Boot ROM */  
   FPUTABLES   : origin = 0x3FEBDC, length = 0x0006A0     /* FPU Tables in Boot ROM */
   ROM         : origin = 0x3FF27C, length = 0x000D44     /* Boot ROM */        
   RESET       : origin = 0x3FFFC0, length = 0x000002     /* part of boot ROM  */
   VECTORS     : origin = 0x3FFFC2, length = 0x00003E     /* part of boot ROM  */
 
PAGE 1 :   /* Data Memory */
           /* Memory (RAM/FLASH/OTP) blocks can be moved to PAGE0 for program allocation */
           /* Registers remain on PAGE1                                                  */
   
   BOOT_RSVD   : origin = 0x000000, length = 0x000050     /* Part of M0, BOOT rom will use this for stack */
   RAMM0       : origin = 0x000050, length = 0x0003B0     /* on-chip RAM block M0 */
   RAMM1       : origin = 0x000400, length = 0x000400     /* on-chip RAM block M1 */
   RAML4       : origin = 0x00C000, length = 0x001000     /* on-chip RAM block L1 */
   RAML5       : origin = 0x00D000, length = 0x001000     /* on-chip RAM block L1 */
   RAML6       : origin = 0x00E000, length = 0x001000     /* on-chip RAM block L1 */
   RAML7       : origin = 0x00F000, length = 0x001000     /* on-chip RAM block L1 */
   ZONE7B      : origin = 0x20FC00, length = 0x000400     /* XINTF zone 7 - data space */
   FLASHB      : origin = 0x330000, length = 0x008000     /* on-chip FLASH */
}

ログイン後にコピー

通常、MEMORY には PAGE0 と PAGE1 が含まれていることがわかります。PAGE0 の RAML0 は、開始アドレス 0x008000、記憶領域長 0x001000 の記憶領域を表します。同様に、他のストレージスペース名の意味も知ることができます。

TI28335 チップデータマニュアル (一部のみ抜粋) を比較すると、上記の cmd ファイルの記述が TI28335 チップデータマニュアルのメモリマッピングセクションに基づいていることがわかります。 cmd ファイルを記述するには、チップデータマニュアルのメモリマッピングのセクションを参照することもできます。

Linuxのcmdファイルとは何ですか

次に、SECTION の内容について、F28335 の cmd ファイルを例に説明します

SECTIONS
{
 
   /* Allocate program areas: */
   .cinit              : > FLASHA      PAGE = 0
   .pinit              : > FLASHA,     PAGE = 0
   .text               : > FLASHA      PAGE = 0
   codestart           : > BEGIN       PAGE = 0
   ramfuncs            : LOAD = FLASHD, 
                         RUN = RAML0, 
                         LOAD_START(_RamfuncsLoadStart),
                         LOAD_END(_RamfuncsLoadEnd),
                         RUN_START(_RamfuncsRunStart),
                         LOAD_SIZE(_RamfuncsLoadSize),
                         PAGE = 0
 
   csmpasswds          : > CSM_PWL     PAGE = 0
   csm_rsvd            : > CSM_RSVD    PAGE = 0
   
   /* Allocate uninitalized data sections: */
   .stack              : > RAMM1       PAGE = 1
   .ebss               : > RAML4       PAGE = 1
   .esysmem            : > RAMM1       PAGE = 1
 
   /* Initalized sections go in Flash */
   /* For SDFlash to program these, they must be allocated to page 0 */
   .econst             : > FLASHA      PAGE = 0
   .switch             : > FLASHA      PAGE = 0      
 
   /* Allocate IQ math areas: */
   IQmath              : > FLASHC      PAGE = 0                  /* Math Code */
   IQmathTables     : > IQTABLES,  PAGE = 0, TYPE = NOLOAD 
   
   /* Uncomment the section below if calling the IQNexp() or IQexp()
      functions from the IQMath.lib library in order to utilize the 
      relevant IQ Math table in Boot ROM (This saves space and Boot ROM 
      is 1 wait-state). If this section is not uncommented, IQmathTables2
      will be loaded into other memory (SARAM, Flash, etc.) and will take
      up space, but 0 wait-state is possible.
   */
   /*
   IQmathTables2    : > IQTABLES2, PAGE = 0, TYPE = NOLOAD 
   {
   
              IQmath.lib<IQNexpTable.obj> (IQmathTablesRam)
   
   }
   */
   
   FPUmathTables    : > FPUTABLES, PAGE = 0, TYPE = NOLOAD 
         
   /* Allocate DMA-accessible RAM sections: */
   DMARAML4         : > RAML4,     PAGE = 1
   DMARAML5         : > RAML5,     PAGE = 1
   DMARAML6         : > RAML6,     PAGE = 1
   DMARAML7         : > RAML7,     PAGE = 1
   
   /* Allocate 0x400 of XINTF Zone 7 to storing data */
   ZONE7DATA        : > ZONE7B,    PAGE = 1
 
   /* .reset is a standard section used by the compiler.  It contains the */ 
   /* the address of the start of _c_int00 for C Code.   /*
   /* When using the boot ROM this section and the CPU vector */
   /* table is not needed.  Thus the default type is set here to  */
   /* DSECT  */ 
   .reset              : > RESET,      PAGE = 0, TYPE = DSECT
   vectors             : > VECTORS     PAGE = 0, TYPE = DSECT
   
   /* Allocate ADC_cal function (pre-programmed by factory into TI reserved memory) */
   .adc_cal     : load = ADC_CAL,   PAGE = 0, TYPE = NOLOAD
 
}

ログイン後にコピー

SECTION には次の内容が含まれていることがわかりますさまざまなセクション名。「.text」を例にとると、「.text」はコンパイル後に生成されるバイナリ命令コードセグメントで、「.text」の内容をFLASHAに割り当てて格納しており、FLASHAはMEMORYのPAGE0に配置されていることがわかります。

SECTION の ramfuncs は 28335 の起動に関連しています。その本質は、電源投入時に「ブートストラッププログラム」を通じて FLASH からユーザーコードを読み取り、RAM に保存して RAM で実行することで、問題を解決することです。 ROMの問題読み書き速度が遅く、高速スマートチップやRAMの停電によるデータ損失の問題に対処するのが困難です。

カスタムセグメント

セグメントに関するこの情報を知ることは、ユーザーにとって何の役に立つのでしょうか?最も直接的な用途は、コンパイラがメモリが不足していることを示すプロンプトを表示したときに、対応するセグメント名を通じて対応する記憶領域を見つけ、プログラムのニーズを満たすようにその記憶領域のサイズを変更できることです。セグメント名をカスタマイズしてコードとデータを保存することもできます。

#pragma DATA_SECTION (関数名またはグローバル変数名、「データ空間のユーザー定義セグメント名」) または #pragma CODE_SECTION (関数名またはグローバル変数名、「プログラム空間のユーザー定義セグメント名」) を渡します。 ") セグメント名") はカスタマイズされたセグメント名を実装できるため、ストレージ領域を自由に割り当てることができます。

#プラグマ DATA_SECTION (変数用)

#pragma CODE_SECTION（用于函数）

但使用以上指令时需注意：不能在函数体内声明必须在定义和使用前声明，#pragma可以阻止对未调用的函数的优化。

下面结合实际使用例子来具体讲解：

#pragma DATA_SECTION(FFT_output, "FFT_buffer1");
float FFT_output[FFT_SIZE];

ログイン後にコピー

笔者声明了一个数据段，段名为FFT_buffer1，段的内容在变量FFT_ouput里。而声明后才定义变量FFT_output的大小。

我们如果想要使用这个自定义的段，接下来我们还要在CMD文件的SECTION中指定FFT_buffer1的存储空间。

FFT_buffer1		: > RAML4,     PAGE = 1

ログイン後にコピー

通过以上几条语句，笔者实现了将变量的内容存放入指定的RAML4存储空间的操作。

从上可以得出，当全局变量所占内存过大时，我们可以通过自定义段选择有所余裕的存储空间的方式，从而来解决内存不足的问题。

Linuxのcmdファイルとは何ですか

cmd ファイルとは何ですか?

MEMORY と SECTION

カスタム セグメント

カスタムセグメント