Excel Chooserows功能可以從數組中提取某些行

在本教程中，我們將深入了解名為Chooserows及其實際用途的Excel 365功能。

假設您有一個具有數百行的Excel工作表，您想從中提取一些特定的工作表，例如，所有奇數甚至行，前5行或最後10行等。不用擔心！一切都比看起來要簡單得多。只需使用新的動態陣列chooserows函數即可。

• Excel Chooserows功能
• 如何在Excel中使用Chooserows功能
• 從數組返回最後的n行
• 提取其他行
• 垂直翻轉陣列
• 從多個陣列中提取行
• 根據字符串獲得數字的行
• Excel Chooserows功能不起作用

Excel Chooserows功能

Excel中的Chooserows函數用於從數組或範圍提取指定的行。

語法如下：

chooserows（array，row_num1，[row_num2]，…）

在哪裡：

數組（必需） - 源數組。

ROW_NUM1 （必需） - 代表要返回第一行的數字索引的整數。

row_num2 ，…（可選） - 要返回的其他行的索引號。

這是Chooserows功能在Excel 365中工作的方式：

chooserows功能可用性

Chooserows函數僅在Microsoft 365（Windows和Mac）的Excel中可用，並且可用於Web。

提示。要從範圍或數組中獲取某些列，請使用ChooseCols函數。

如何在Excel中使用Chooserows功能

要從給定數組中拉出特定的行，請以這種方式構建一個choserows公式：

1. 對於數組，您可以提供一系列單元格或由另一公式驅動的值。
2. 對於Row_num ，提供一個正或負整數，指示要返回哪一行。正數從數組的開頭檢索相應的行，一個負數 - 從數組的末端。可以在單獨的參數中單獨提供多個行號，也可以在一個參數中以數組常數的形式提供。

作為Excel動態陣列函數，ChooSerows本地處理數組。您可以在目標範圍的左上方單元格中輸入公式，並根據需要自動溢出到盡可能多的列和行中。結果是單個動態陣列，也稱為溢出範圍。

例如，要從A4：D13範圍獲得2、4、6、8和10行，該公式為：

=CHOOSEROWS(A4:D13, 2, 4, 6, 8, 10)

另外，您可以使用數組常數，例如{2,4,6,8,10}或{2; 4; 6; 6; 8; 10}來指定所需的行：

=CHOOSEROWS(A4:D13, {2,4,6,8,10})

或者

=CHOOSEROWS(A4:D13, {2;4;6;8;10})

提供行號的另一種方法是在單獨的單元格中輸入它們，然後將單個單元格引用用於多個row_num參數或單個行_num參數的範圍參考。

例如：

=CHOOSEROWS(A4:D13, F4, G4, H4)

=CHOOSEROWS(A4:D13, F4:H4)

這種方法的一個優點是，它使您可以通過簡單地更改預定義單元格中的數字而無需編輯公式本身來提取任何其他行。

在下面，我們將討論其他一些Chooserows公式示例，以處理更具體的用例。

從數組末端返回行

要快速從範圍獲得最後的n行，請為Row_num參數提供負數。這將迫使該函數從數組末端計數行。

例如，要從範圍A4：D13範圍內獲取最後3行，請使用此公式：

=CHOOSEROWS(A4:D13, -3, -2, -1)

結果將是一個3行陣列，其中行以與引用範圍相同的順序出現。

要以相反順序返回最後3行，從下到頂部，更改Row_num參數的順序：

=CHOOSEROWS(A4:D13, -1, -2, -3)

從Excel中的數組中提取其他行

要從給定的範圍中獲取其他行，請將Chooserows與其他一些功能結合使用。該公式會根據您是提取奇數甚至行而變化的。

要返回諸如1、3、5的奇數行，……該公式採用此形式：

=CHOOSEROWS(A4:D13, SEQUENCE(ROUNDUP(ROWS(A4:D13)/2, 0), 1, 1, 2))

返回諸如2、4、6之類的行，……公式如下：

=CHOOSEROWS(A4:D13, SEQUENCE(ROUNDDOWN(ROWS(A4:D13)/2, 0), 1, 2, 2))

該公式如何工作：

從本質上講，Chooserows函數基於序列函數生成的順序奇數或偶數數字返回行。下面有詳細的公式分解。

首先，您確定要返回多少行。為此，您採用行函數來獲取參考陣列中的行總數，然後將其除以2，然後在綜述或往返的幫助下向上或向下繞過數字。由於此數字將稍後將其提供給序列的行參數，因此需要捨入以獲取一個整數，以防源範圍包含奇數行。

由於我們的源範圍具有偶數的行（10），這些行數（10）恰好劃分為2，因此綜述（10/2，0）和倒陣（10/2，0）返回相同的結果，即5。

返回的數字被送給序列函數。

對於奇數行：

SEQUENCE(5, 1, 1, 2)

對於行：

SEQUENCE(5, 1, 2, 2)

上面的序列公式會產生一個由5行和1列組成的數字數組，從奇數行開始為1（偶數行2），並增加2。

對於奇數行，我們得到此數組：

{1;3;5;7;9}

對於行，我們得到了一個：

{2;4;6;8;10}

生成的數組轉到Chooserows的Row_num1參數，您將獲得所需的結果：

=CHOOSEROWS(A4:D13, {1;3;5;7;9})

反向數組中的行順序

要從頂部到底垂直翻轉數組，您也可以一起使用Chooserows和序列功能。例如：

=CHOOSEROWS(A4:D13, SEQUENCE(ROWS(A4:D13))*-1)

在此公式中，我們僅設置序列的第一個參數（行），該序列等於初始數組行中的行總數（A4：D13）。省略的參數（列，啟動，步驟）默認為1。結果，序列會產生順序數字的數組，例如1、2、3，…，N，其中N是源數組中的最後一行。為了使choserows沿向上方向計數行，生成的序列乘以-1，因此Row_num參數獲得了一個負數數組，例如{-1; -2; -2; -3; -4; -4; -5; -5; -6; -8; -8; -8; -9; -9; -10}。

結果，每列中的項目順序從上到下更改：

從多個陣列中提取行

要從兩個或多個非連續範圍中獲取特定的行，您首先使用VSTACK函數將它們組合起來，然後將合併範圍傳遞給Chooserows。

例如，要從範圍A4：D8和最後兩個行中提取前兩個行，請使用此公式：

=CHOOSEROWS(VSTACK(A4:D8, A12:D16), 1, 2, -2, -1)

根據包含行號的字符串獲取行

此示例顯示瞭如何通過從alpha數字字符串中提取數字來返回特定行。

假設您在單元格列出了感興趣的行中的逗號分隔數。要從字符串中提取行號，請使用可以將文本字符串拆分為給定定界符（在我們的情況下逗號）的文本函數：

=TEXTSPLIT(G3, ",")

結果是一系列文本值，例如{“ 3”，“ 5”，“ 7”，“ 10”}。要將其轉換為數字數組，請執行任何不更改值的數學操作，例如0或 *1。

=TEXTSPLIT(G3, ",") *1

這會產生ChooSerows功能需要的數字數組常數{3,5,7,10}，因此您將textSplit公式嵌入2 ^nd參數：

=CHOOSEROWS(A4:D13, TEXTSPLIT(G3, ",") *1)

結果，所有指定的行都以一個數組的形式返回：

chooserows功能不起作用

如果Chooserows公式會導致錯誤，則最有可能是這些原因之一。

＃價值！錯誤

如果任何row_num參數的絕對值為零或高於數組中的行總數為零或更高，則會發生。

＃姓名？錯誤

如果函數的名稱拼寫錯誤或excel中不支持該功能，則會發生。當前，ChooSerows僅在Excel 365中可用，並且可以用於Web。有關更多詳細信息，請閱讀如何在Excel中修復#NAME錯誤。

＃灑！錯誤

當沒有足夠的空白細胞填充結果時，就會發生。要修復它，只需清除阻塞細胞即可。有關更多信息，請參閱Excel #spill！錯誤。

這就是如何使用excel中的chooserows函數從範圍或數組中返回特定行。感謝您的閱讀，希望下週在我們的博客上見到您！

練習工作簿下載

Excel Chooserows公式 - 示例（.xlsx文件）

以上是Excel Chooserows功能可以從數組中提取某些行的詳細內容。更多資訊請關注PHP中文網其他相關文章！