具有公式示例的Excel PMT功能

該教程顯示瞭如何在Excel中使用PMT功能來根據利率，付款數量和貸款總額來計算貸款或投資的付款。

在藉錢之前，很高興知道貸款如何運作。得益於Excel財務功能，例如利率，PPMT和IPMT，計算每月或任何其他定期貸款付款非常容易。在本教程中，我們將仔細研究PMT函數，詳細討論其語法，並展示如何在Excel中構建自己的PMT計算器。

• Excel中的PMT功能是什麼？
• Excel PMT功能 - 語法和基本用途
• 如何在Excel中使用PMT公式 - 示例
  • PMT功能的完整形式
  • 每週，每月，季度和半年度付款的PMT公式
• 如何在Excel中創建PMT計算器
• Excel PMT功能不起作用

Excel中的PMT功能是什麼？

Excel PMT功能是一種財務功能，可根據恆定利率，期限和貸款金額計算貸款的付款。

“ PMT”代表“付款”，因此該函數的名稱。

例如，如果您要申請為期兩年的汽車貸款，年利率為7％，貸款金額為30,000美元，PMT公式可以告訴您您的每月付款方式。

要使PMT功能在工作表中正確工作，請記住以下事實：

• 要符合一般現金流模型，付款金額作為負數數字，因為它是現金流出。
• PMT功能返回的價值包括本金和利息，但不包括可能與貸款相關的任何費用，稅收或儲備金。
• Excel中的PMT公式可以計算不同付款頻率的貸款付款，例如每週，每月，每季度或每年。此示例顯示瞭如何正確執行操作。

PMT功能可在Office 365，Excel 2019，Excel 2016，Excel 2013，Excel 2013，Excel 2010和Excel 2007中獲得PMT功能。

Excel PMT功能 - 語法和基本用途

PMT功能具有以下參數：

PMT（速率，nper，PV，[fv]，[type]）

在哪裡：

• 利率（必需） - 每個期間的恆定利率。可以以百分比或十進制數字提供。

  例如，如果您以每年的利率為10％的貸款付款，則使用10％或0.1的利率。如果您每月支付相同的貸款付款，請使用10％/12或0.00833的費率。

• nper （必需） - 貸款的付款數量，即應支付貸款的總數。

  例如，如果您通過5年貸款進行年度付款，則為NPER提供5。如果您每月支付相同的貸款付款，則將年數乘以12年，然後使用5*12或60的nper。

• PV （必需） - 現值，即所有未來付款現在價值的總金額。如果貸款，這僅僅是原始金額。
• FV （可選） - 上次付款後希望擁有的未來價值或現金餘額。如果省略，則假定貸款的未來價值為零（0）。
• 類型（可選） - 指定付款到期何時：
  • 0或省略 - 每個時期結束時付款應到期。
  • 1-付款應在每個時期開始。

例如，如果您在5年內借入100,000美元，年利率為7％，則以下公式將計算年度付款：

=PMT(7%, 5, 100000)

要查找同一貸款的每月付款，請使用此公式：

=PMT(7%/12, 5*12, 100000)

或者，您可以在單獨的單元格中輸入貸款的已知組件，並在PMT公式中引用這些單元格。在B1中的利率，沒有。在B2中的年份和B3中的貸款金額，該公式很簡單：

=PMT(B1, B2, B3)

請記住，付款作為負數退還，因為該金額將從您的銀行帳戶中扣除（減）。

默認情況下，Excel以貨幣格式顯示結果，舍入到2個小數點位置，以紅色和括號中的封閉方式突出顯示，如下圖所示。右側的圖像以通用格式顯示相同的結果。

如果您想將付款作為正數，請在整個PMT公式或PV參數（貸款金額）之前放一個減號：

=-PMT(B1, B2, B3)

或者

=PMT(B1, B2, -B3)

提示。要計算貸款支付的總金額，請將返回的PMT值乘以期限數（NPer值）。在我們的情況下，我們將使用此等式：24,389.07*5，發現總金額等於$ 121,945.35。

如何在Excel-公式示例中使用PMT函數

在下面，您會找到更多的Excel PMT公式的示例，這些示例顯示瞭如何計算汽車貸款，房屋貸款，抵押貸款等不同周期性付款。

Excel中PMT功能的完整形式

在大多數情況下，您可以省略PMT公式中的最後兩個參數（就像我們在上面的示例中一樣），因為它們的默認值涵蓋了最典型的用途：

• 省略FV - 表示上次付款後零餘額。
• 省略類型- 付款應在每個時期結束時進行。

如果您的貸款條件與默認值不同，請使用PMT公式的完整形式。

例如，讓我們計算基於這些輸入單元的年度付款量：

• B1-年利率
• B2-貸款期限（年）
• B3-貸款金額
• B4-未來價值（上次付款後的餘額）
• B5-年金類型：
  • 0（常規年金） - 每年年底進行付款。
  • 1（應付年金） - 付款是在此期間開始的，例如租金或租賃付款。

將這些引用提供給您的Excel PMT公式：

=PMT(B1, B2, B3, B4, B5)

您將獲得此結果：

計算每週，每月，季度和半年度付款

根據付款頻率，您需要使用以下計算來進行速率和nper參數：

• 為了利率，將年利率除以每年的付款數量（被認為等於復合期的數量）。
• 對於nper ，將年數乘以每年的付款數量。

下表提供了詳細信息：

付款頻率	速度	nper
每週	年利率 / 52	年 * 52
每月	年利率 / 12	年 * 12
季刊	年利率 / 4	年 * 4
半年度	年利率 / 2	年 * 2

例如，為了找到5,000美元的貸款定期付款的金額，年利率為8％，持續時間為3年，請使用以下公式之一。

每週付款：

=PMT(8%/52, 3*52, 5000)

每月付款：

=PMT(8%/12, 3*12, 5000)

季度付款：

=PMT(8%/4, 3*4, 5000)

半年度付款：

=PMT(8%/2, 3*2, 5000)

在所有情況下，假定上次付款後的餘額為$ 0，並且付款應在每個時期結束時到期。

下面的屏幕截圖顯示了這些公式的結果：

如何在Excel中製作PMT計算器

在您繼續借錢之前，有理由比較不同的貸款條件，以找出最適合您的選擇。為此，讓我們創建自己的Excel貸款付款計算器。

1. 首先，在單獨的單元格中輸入貸款金額，利率和貸款期限（分別為b3，b4，b5）。
2. 為了能夠選擇不同的期間並指定付款何時到期，請創建下拉列表，並使用以下預定義的選項（B6和B7）：

   

3. 設置時期（E2：F6）的查找表，付款應到期（E8：F9），如下面的屏幕截圖所示。查找表中的文本標籤與相應的下拉列表的項目完全匹配，這一點很重要。在下拉列表旁邊的單元格中，輸入以下IFERROR VLOOKUP公式，該公式將從查找表中拉出與下拉列表中選擇的項目相對應的數字。

   時期公式（C6）：

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   付款公式應到期（C7）：

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. 編寫PMT公式以根據您的單元格計算定期付款。在我們的情況下，該公式如下：

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   請注意以下內容：

   • FV參數（0）是在公式中進行了硬編碼的，因為我們始終希望在上次付款後零餘額。如果您希望允許您的用戶輸入任何未來值，請為FV參數分配單獨的輸入單元格。
   • PMT函數先於減去符號，以將結果顯示為正數。
   • 當未定義某些輸入值時，將PMT函數包裹到IFERROR中以隱藏錯誤。

   上述公式在B9中。在相鄰的單元格（A9）中，我們顯示與所選時期相對應的標籤（B6）。為此，只需將B6和所需文本中的值串聯：

   =B6&" Payment"

   

5. 最後，您可以從視圖中隱藏查找表，添加一些修飾格式觸摸，並且您的Excel PMT計算器很適合：

   

Excel PMT功能不起作用

如果您的Excel PMT公式無法正常工作或產生錯誤的結果，則可能是由於以下原因：

• #num！如果速率參數為負數或NPER等於0，則可能發生錯誤。
• #value！如果一個或多個參數是文本值，則會發生錯誤。
• 如果PMT公式的結果比預期的要高得多或高得多，請確保您與速率和NPer論點的單位一致，這意味著您已正確將年利率轉換為該期間的利率以及本示例所示的年度，幾週，幾個月或四分之一的年限。

這就是您在Excel中計算PMT功能的方式。要仔細查看本教程中討論的公式，歡迎下面下載我們的示例工作簿。我感謝您閱讀，並希望下週在我們的博客上見到您！

練習工作簿下載

Excel中的PMT公式 - 示例（.xlsx文件）

以上是具有公式示例的Excel PMT功能的詳細內容。更多資訊請關注PHP中文網其他相關文章！