linux bison是什麼-linux運維-PHP中文網

在linux中，bison是用來產生語法分析器程式的工具，它可以將使用者提供的語法規則轉換成一個語法分析器；bison需要和flex（詞法分析器）配合使用來處理複雜的文件解析工作。透過給定語法的產生式開始，bison會透過演算法，最終構造得到動作表，然後利用這個動作表去解析句子。

linux bison是什麼

本教學操作環境：linux7.3系統、Dell G3電腦。

Unix Lex/YACC 發展為Linux FLex/Bison

Lex是1975年由Mike Lesk和當時尚在AT&T實習的Eric Schmidt共同完成的（Schmidt做的更多），是一個詞法分析器的生成程序，可以單獨使用也可以與Johnson的yacc協同工作。 lex很有名氣，但無奈效率太低加上有bug。大概在1987年，Lawrence Berkeley實驗室的Vern Paxson用C重新寫了Lex，並命名為FLex（the Fast Lexical Analyzer Generator），基於柏克萊許可證。 flex現在是SourceForge的一個項目，依然基於伯克利許可，
[Flex](https://github.com/westes/flex "Flex") 是起初unix版lex的free (but non-GNU) implementation，用於c/c 的詞法掃描生成器。

（註：Schmidt曾是google的CEO）

bison的前身是yacc。 yacc是由貝爾實驗室的S.C.Johnson基於Knuth大神的LR語法分析理論，於1975～1978年寫成。大約在1985年，UC Berkeley 的研究生Bob Corbett使用改進的內部演算法實現了伯克利yacc，來自FSF的Richard Stallman改寫了伯克利yacc並將其用於GNU項目，添加了許多特性，形成了今天的GNU Bison。 bison現在作為FSF的專案被維護，基於GNU公共授權發布，[Bison](http://www.gnu.org/software/bison/manual/)是相容於yacc的free的語法產生器。

早期Unix的Lex/YACC，發展為FLex/Bison，新版的程式是向上相容的(即相容舊版)，現chang用Flex和Bison。

flex/bison工作原理

使用的角度，Flex和Bison是Linux下用來產生詞法分析器和語法分析器兩個程式的工具，可以處理結構化輸入，一般結合使用來處理複雜的文件解析工作。

linux bison是什麼

bison可以將使用者提供的語法規則轉換成語法分析器。簡單來說，透過給定語法的產生式開始，bison會透過演算法，最後構造得到動作表，然後利用這個動作表去解析句子。具體來說，bison 讀取使用者提供的語法的產生式，產生一個C 語言格式的LALR(1) 動作表，並將其包含進一個名為yyparse的C 函數，這個函數的作用就是利用這個動作表來解析token 流，而這個token 流是由flex 產生的詞法分析器掃描原始程式得到的。

flex檔案是定義pattern（哪是黃豆，哪是綠豆...），透過flex處理（詞法分析）將輸出切分成一段一段的token（將輸入的豆子一個個摘出來），從而執行不同的action（黃豆就磨豆漿（action），綠豆去做綠豆糕(action)）...
flex 生成的tokens可以餵給Bison處理（更簡單易調試），當然也可以不餵給bison而直接自己處理就得了（如喜下例）。但使用bison可以更方便的處理複雜的邏輯，編寫簡單，調試方便。

編碼實戰：字元統計器

//本例中仅仅使用flex以及少量手写代码（main中），来完成字符串统计功能。
Yolandas-MacBook-Pro:flex-bison liuyuanyuan$ cat fb1-1.l
/* 统计输入字符串*/
%{
  int chars = 0;
  int words = 0;
  int lines =0;

%}

%%
[a-zA-Z]+ {
		words++;
		chars += strlen(yytext);
          }

\n        {     chars++; lines++;}

.         {     chars++;     }

%%


int main(int args, char **argv)
{
	yylex();
	printf("lines=%6d words=%6d chars=%6d\n", lines, words, chars);
	return 0;
}

//Linux 系统上用 -lfl 选项编译, Mac 的编译选项是 -ll
Yolandas-MacBook-Pro:flex-bison liuyuanyuan$ gcc -ll lex.yy.c  -o fb1-1
Yolandas-MacBook-Pro:flex-bison liuyuanyuan$ ./fb1-1
hello 
this is yolanda
bye.
lines=     3 words=     5 chars=    28

登入後複製

1 **flex(fast lex, scanner)檔案內容結構（*.l,** #分為3部分）

/* P1: declarations(定义段) */
%{
  
%}

%%
  /* P2: translation rules(规则段) */
%%

/* P3: auxiliary functions(用户辅助程序段，c函数)*/

登入後複製

定義段落 包括文字區塊、定義、內部宣告等。
C語言的頭檔、函數和變數的宣告等一般就放在%{…%}之間，這部分的內容會被直接複製到產生.c檔的開頭部分。

包含%option選項

%option noyywrap /* 定义段中包含了option选项*/

%{
#include "cal.tab.h"
extern int yylval;
%}

登入後複製

規則段 %%...%%之間部分，為一系列符合模式(正規表示式)和動作(C程式碼)。

當flex掃描程式運行時，它把輸入與規則段的模式進行匹配，每次發現一個匹配（被匹配的輸入稱為標記（token））時就執行與那種模式相關的C代碼。

pattern（正则表达式） { action(c代码) }

example:
[0-9]+ {yylval = atoi(yytest); return NUMBER;}

登入後複製

使用者輔助程式段 為C程式碼，會被原樣複製到c檔中，一般這裡定義一些輔助函數等。

int terror(chr *s)
{
    printf("%s\n", s);
    return 0;
}

登入後複製

**2 bison(yacc, parser)檔案內容結構（*.y ,** 分成3部分，%%分隔）

/*P1: declarations 定义段*/
%{

%}
 
%%
/*P2: grammar rules 规则段(rule-action)*/
    
     A: a1  {  语义动作1 }
	  | a2  {  语义动作2 }
	  | …
	  | an  {  语义动作n }
	  | b  //没有{…},则使用缺省的语义动作       
	; //产生式结束标记
    //语义动作一般是在产生式右部分析完，归约动作进行前执行。
    A→ a1 | a2 |  … | an | b 
%%

/* P3: supporting C routines 用户辅助程序段(C函数) */

登入後複製

#定義段落 可以分為兩個部分：

1. %{ 和%}之間的部分，C語言寫的，包括頭檔include、巨集定義、全域變數定義、函數宣告等;

2. 對文法的終結符和非終結符做一些相關聲明。

常用的Bison標記宣告有：%token %union %start %type %left %right %nonassoc等。

%token 定义文法中使用了哪些终结符。定义形式： %token TOKEN1 TOKEN2
终结符一般全大写；（如 TOKEN1 TOKEN2）
一行可定义多个终结符，空格分隔；

%left、%right、%nonassoc 也是定义文法中使用了哪些终结符。定义形式与%token类似。
先定义的优先级低，最后定义的优先级最高，同时定义的优先级想通过。
%left表示左结合，%right表示右结合；
%nonassoc 表示不可结合（即它定义的终结符不能连续出现。例如
%left AA BB
%nonassoc CC
%right DD
表示优先级关系为：AA=BB 注意：也可以于%prec来结合使用来改变token的优先级和结合性例如： :'-' expr %prec NEG { $$ = -$2; };

%union 声明语法符号的语义值类型的集合，
bison中每个符号包括记号和非终结符都有一个不同数据类型的语义值，并使用yylval变量在移进和归约中传递这些值，YYSTYPE（宏定义）为yylval的类型，默认为int；
我们使用%union来重新定义符号的类型
%union
{
int iValue; /* integer value */
char sIndex; /* symbol table index */
nodeType *nPtr; /* node pointer */
};

%type 定义非终结符其属性值的类型。
%type sym1 sym2
%type sym3

%start 指定文法的开始的文法符号（非终结符），是最终需要规约而成的符号。
定义形式为：%start startsym ，其中startsym为文法的开始符号。
如果不使用%start定义文法开始符号，则默认在第二部分规则段中定义的第一条生产式规则的左部非终结符为开始符号。

规则段 由rule(语法规则)和action(包括C代码)组成。

bison规则基本是BNF，做了一点简化以易于输入。

规则中目标或非终端符放在左边，后跟一个冒号：然后是产生式的右边，之后是对应的动作（用{}包含）。

%%
  program: program expr '\n' { printf("%d\n", $2); }
  ;

  expr: INTEGER {$$ = $1; }
           | expr '+' expr { $$ = $1 + $3; }
           | expr '-' expr { $$ = $1 - $3}
  ;
%%

登入後複製

注意：$1表示右边的第一个标记的值，$2表示右边的第二个标记的值，依次类推。$$表示归约后的值。

linux bison是什麼

用户辅助程序段 为C代码，会被原样复制到c文件中，这里一般自定义一些函数。

3 flex-bison 代码协作方式

linux bison是什麼

flex/bison编码实践：编写简单计算器

1 macOS下flex/bison安装

brew install flex
brew install bison
# macos下flex/bison安装简单方便，另需安装gcc用于编译c语言程序。
brew install gcc

登入後複製

2 flex词法文件：calc.l

%option noyywrap

%{
    /*
     *  一个简单计算器的Lex词法文件
     */
	void yyerror(char*);
	#include "calc.tab.h"
%}

%%

     /* a-z为变量 */   
[a-z]	{
            yylval = *yytext - 'a';
            return VARIABLE;
    	}

    /* 整数 */
[0-9]+	{
            yylval = atoi(yytext);
            return INTEGER;
    	}

    /* 运算符 */
[-+()=/*\n]	{return *yytext;}

    /* 空白被忽略 */
[ \t]    ;

    /* 其他字符都是非法的 */
.    yyerror("invalid input");

%%

登入後複製

3 bison语法文件：calc.y

%token    INTEGER VARIABLE
%left    '+' '-'
%left    '*' '/'

%{
	#include <stdio.h>   
    void yyerror(char*);
    int yylex(void);
	
    int sym[26];
%}

%%
program:
    program statement '\n'
    |
    ;
statement:
     expr    {printf("%d\n", $1);}
     |VARIABLE '=' expr    {sym[$1] = $3;}
     ;
expr:
    INTEGER
    |VARIABLE{$$ = sym[$1];}
    |expr '+' expr    {$$ = $1 + $3;}
    |expr '-' expr    {$$ = $1 - $3;}
    |expr '*' expr    {$$ = $1 * $3;}
    |expr '/' expr    {$$ = $1 / $3;}
    |'('expr')'    {$$ = $2;}
    ;
%%

void yyerror(char* s)
{
    fprintf(stderr, "%s\n", s);
}

int main(void)
{
    printf("A simple calculator.\n");
    yyparse();
    return 0;
}</stdio.h>

登入後複製

4 Makefile 文件：

all: clean calc


calc: calc.l calc.y
	bison -d calc.y
	flex calc.l
	cc -o $@ calc.tab.c lex.yy.c -lm

clean:
	rm -f calc \
	lex.yy.c calc.tab.c calc.tab.h

登入後複製

5 执行

(可以直接执行make也就是执行Makefile中定义的内容，也可以单步执行)

Yolandas-MBP:calcSimple liuyuanyuan$ ls -l
total 32
-rw-r--r--@ 1 liuyuanyuan  staff  157  8 13 09:53 Makefile
-rw-r--r--@ 1 liuyuanyuan  staff  507  8 13 10:01 calc.l
-rw-r--r--@ 1 liuyuanyuan  staff  731  8 13 23:04 calc.y

Yolandas-MBP:calcSimple liuyuanyuan$ make
rm -f calc \
	lex.yy.c calc.tab.c calc.tab.h
bison -d calc.y
flex calc.l
cc -o calc calc.tab.c lex.yy.c -lm

Yolandas-MBP:calcSimple liuyuanyuan$ ls -l
total 272
-rw-r--r--@ 1 liuyuanyuan  staff    157  8 13 09:53 Makefile
-rwxr-xr-x  1 liuyuanyuan  staff  24600  8 14 12:00 calc
-rw-r--r--@ 1 liuyuanyuan  staff    507  8 13 10:01 calc.l
-rw-r--r--  1 liuyuanyuan  staff  42011  8 14 12:00 calc.tab.c
-rw-r--r--  1 liuyuanyuan  staff   2143  8 14 12:00 calc.tab.h
-rw-r--r--@ 1 liuyuanyuan  staff    731  8 13 23:04 calc.y
-rw-r--r--  1 liuyuanyuan  staff  44590  8 14 12:00 lex.yy.c

Yolandas-MBP:calcSimple liuyuanyuan$ ./calc
A simple calculator.
1+2
3

登入後複製

以上是linux bison是什麼的詳細內容。更多資訊請關注PHP中文網其他相關文章！