支持 Pascal 函数-Golang-PHP中文网

Suporte às funções do Pascal

对于那些不遵循 POJ（JVM 上的 Pascal）的人来说，它是一个将子集从 Pascal 转换为 JASM 的编译器（ Java Assembly），以便我们可以使用 JVM 作为执行环境。

在上一篇文章中，我们在错误捕获、对 string 类型的关系运算符的支持以及定义（和使用）Pascal 的过程的可能性。

在本出版物中，我们将介绍对 Pascal 函数（函数）的支持。不久之后我们就可以完成该项目的最后一个目标：从标准输入中读取一个数字并计算其阶乘。

当我们为 JVM 进行编译时，有必要详细说明这个令人难以置信的虚拟机的各个点的功能。因此，我多次详细介绍 JVM 的内部功能及其一些指令（操作码）。

支持 Pascal 函数（函数）

到目前为止，我们有一种方法来定义和调用 Pascal 的过程。从此 PR 中还可以定义和调用 Pascal 的函数.

在此提交中，实现了一个 Java 程序来了解 JVM 如何处理定义和调用函数。来自下面的 Java 程序：

public class FunctionCall {
    public static void main(String[] args) {
        System.out.println("Hello from main!");
        System.out.println(myMethod());
    }

    static String myMethod() {
        return "Hello from myMethod!";
    }
}

登录后复制

当我们反汇编类时，我们得到以下程序集：

1:  public class FunctionCall {
2:      public static main([java/lang/String)V {
3:          getstatic java/lang/System.out java/io/PrintStream
4:          ldc "Hello from main!"
5:          invokevirtual java/io/PrintStream.println(java/lang/String)V
6:
7:          getstatic java/lang/System.out java/io/PrintStream
8:          invokestatic FunctionCall.myMethod()java/lang/String
9:          invokevirtual java/io/PrintStream.println(java/lang/String)V
10:
11:         return
12:     }
13:
14:     static myMethod()java/lang/String {
15:         ldc "Hello from myMethod!"
16:
17:         areturn
18:     }
19: }

登录后复制

通过这个例子可以确定：

为了调用方法，JVM 使用指令“invokestatic FunctionCall.myMethod()java/lang/String”（第 8 行），其中：
- invokestatic 是接收要调用的方法的完整签名作为参数的指令；
- FunctionCall 是类的名称；
- myMethod()java/lang/String 是方法的完整签名及其参数（在本例中没有）和返回类型（在本例中 java/lang/String） ;
指令areturn（第17行）终止函数并将返回字符串留在堆栈上。

也就是说，来自下面的 Pascal 程序：

program function_call_wo_params;

function myfunction : string;
begin
    myfunction := 'Hello from myfunction!';
end;

begin
    writeln('Hello from main!');
    writeln(myfunction());
end.

登录后复制

POJ 已调整为生成以下 JASM：

// Code generated by POJ 0.1
public class function_call_wo_params {
    ;; function myfunction : string;
    static myfunction()java/lang/String {
        ldc "Hello from myfunction!"
        astore 100   ;; Posição 100 guarda o retorno da função
        aload 100    ;; Empilha o retorno da função
        areturn      ;; Deixa "Hello from myfunction!" na pilha
    }

    ;; procedure principal (main)
    public static main([java/lang/String)V {
        ;; writeln('Hello from main!');
        getstatic java/lang/System.out java/io/PrintStream
        ldc "Hello from main!"
        invokevirtual java/io/PrintStream.print(java/lang/String)V
        getstatic java/lang/System.out java/io/PrintStream
        invokevirtual java/io/PrintStream.println()V

        ;; writeln(myfunction());
        getstatic java/lang/System.out java/io/PrintStream
        invokestatic function_call_wo_params.myfunction()java/lang/String 
        invokevirtual java/io/PrintStream.print(java/lang/String)V
        getstatic java/lang/System.out java/io/PrintStream
        invokevirtual java/io/PrintStream.println()V

        return
    }
}

登录后复制

最细心的人一定注意到了上面的“astore 100”并想到：

为什么将函数返回值存储在局部变量中？这是因为在 Pascal 中，函数的返回值在函数执行期间可以设置 N 次，但我们在 JVM 中只能堆栈一次结果；
为什么排在第 100 位？函数或过程的局部变量从位置 0 开始，因此任意选择位置 100 来存储返回值；
但是是否可以进行优化，以便在此示例中仅生成 ldc "Hello from myfunction!" 指令，然后生成 areturn 指令？是的，确实如此，但 POJ 并未实现市场编译器中存在的优化阶段，而这在未来可能会实现。

此提交实现了对符号表和解析器中的“函数”类型的支持。

在上面的示例中，函数没有参数。在此提交中，实现了带有参数的函数的预期结果。来自下面的 Pascal 程序：

program function_call_with_two_params;

function addvalues(value1, value2: integer) : integer;
begin
    addvalues := value1 + value2;
end;

begin
    writeln('2+4=', addvalues(2, 4));
end.

登录后复制

POJ 正确生成了以下 JASM：

// Code generated by POJ 0.1
public class function_call_with_two_params {
    ;; function addvalues(value1, value2: integer) : integer;
    static addvalues(I, I)I {
        ;; addvalues := value1 + value2;
        iload 0
        iload 1
        iadd 
        istore 100
        iload 100

        ireturn 
    }

    ;; procedure main
    public static main([java/lang/String)V {
        ;; writeln('2+4=', ...);
        getstatic java/lang/System.out java/io/PrintStream
        ldc "2+4="
        invokevirtual java/io/PrintStream.print(java/lang/String)V
        getstatic java/lang/System.out java/io/PrintStream

        ;; aqui código para invocar addvalues(2, 4)
        sipush 2
        sipush 4
        invokestatic function_call_with_two_params.addvalues(I, I)I 

        ;; aqui código para invocar writeln com retorno addvalues
        invokevirtual java/io/PrintStream.print(I)V
        getstatic java/lang/System.out java/io/PrintStream
        invokevirtual java/io/PrintStream.println()V

        return
    }
}

登录后复制