如何计算生日的年龄

该教程显示出不同的方式从Excel中生日。您将学习一些公式，以计算年龄为多年的年龄，在今天的日期或特定日期中以年，几个月和几天的形式获得确切的年龄。

没有特殊的功能可以计算Excel年龄，但是有几种不同的方式将出生日期转换为年龄。本教程将解释每种方式的优点和缺点，并显示如何在Excel中制定完美的年龄计算公式并调整以解决某些特定任务。

• 如何计算出excel的出生日期的年龄
  • 将年龄计算为全年数量
  • 从年龄，几个月和几天开始获得出生日期
• Excel中年龄公式的更多示例
  • 计算特定日期的年龄
  • 在一年中年龄
  • 当一个人年满时计算
  • 从不同细胞的日，月和一年开始年龄
• Excel中的年龄计算器
  • 如何在Excel中创建年龄计算器
  • Excel的现成年龄计算器
• 突出显示特定年龄以下或以上的年龄

如何计算出excel的出生日期的年龄

在日常生活中，“您几岁？ ”通常意味着答案，表明您还活着多少年。在Microsoft Excel中，您可以制作一个公式来计算几个月，几天，小时甚至分钟的精确年龄。但是，让我们成为传统，并学习如何在几年内从DOB中计算年龄。

年龄的基本Excel公式

您通常如何找出某人的年龄？只需从当前日期减去出生日期即可。这种常规的年龄公式也可以在Excel中使用。

假设出生日期在细胞B2中，那么计算年龄的公式如下：

=(TODAY()-B2)/365

公式的第一部分（今天（） - b2）返回当前日期和出生日期之间的差异，然后将该数字除以365，以获取年数。

该公式是明显且易于记住的，但是有一个很小的问题。在大多数情况下，它返回一个小数号，如下面的屏幕截图所示。

要显示完整年的数量，请使用INT功能将小数点舍入到最近的整数：

=INT((TODAY()-B2)/365)

缺点：在Excel中使用此年龄公式会产生相当准确的结果，但并非完美无缺。在大多数情况下，一年中平均数量的平均天数可以正常工作，但有时会使年龄错误。例如，如果某人于2月29日出生，今天是2月28日，则该公式将使一个人有一天。

作为替代方案，您可以除以365.25而不是365，因为每四年级有366天。但是，这种方法也不是完美的。例如，如果您正在计算尚未过跨越一年的孩子的年龄，则除以365.25会产生错误的结果。

总体而言，从当前日期中减去出生日期在正常生活中效果很好，但不是Excel的理想方法。在本教程中，您将学习一些特殊功能，这些功能不管年度如何，都可以无限计算年龄。

通过年龄段功能从出生日期开始计算年龄

将DOB转换为Excel年龄的一种更可靠的方法是使用返回一年部分的年度FRAC功能，即在两个日期之间的整天数量。

年度FRAC函数的语法如下：

年frac（start_date，end_date，[基础]）

前两个论点很明显，几乎不需要任何其他解释。基础是一个可选的论点，它定义了使用的日计数基础。

为了制定完美的年龄公式，请为年度FRAC函数提供以下值：

• start_date-出生日期。
• end_date-今天（）函数返回今天的日期。
• 基础- 使用基础1告诉Excel将实际天数除以每年的实际天数。

考虑到上述内容，从出生日期开始计算年龄的Excel公式如下：

年弗拉克（出生日期，今天（），1）

假设生日在细胞B2中，则该公式采用以下形状：

=YEARFRAC(B2, TODAY(), 1)

像上一个示例一样，年度FRAC函数的结果也是十进制数字。要解决此问题，请在最后一个参数中使用0次数，因为您不需要小数点。

因此，这是计算Excel年龄的改进的年度FRAC公式：

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

用日期计算Excel的年龄

将出生日期转换为Excel年龄的另一种方法是使用日期功能：

日期（start_date，end_date，unit）

此功能可以返回各个时间单元中两个日期之间的差异，例如年，几个月和几天，具体取决于您在单位参数中提供的价值：

• Y-返回开始日期和结束日期之间的完整年数。
• M-返回日期之间的完整月数。
• D-返回两个日期之间的天数。
• YM-返回几个月，忽略天数。
• MD-返回几天的差异，忽略了几个月和几年。
• YD-返回几天的差异，忽略了几年。

由于我们的目标是计算年龄，因此我们使用“ Y”单元：

日期（出生日期，今天（），“ y”）

在此示例中，DOB在单元格B2中，您以年龄公式引用此单元格：

=DATEDIF(B2, TODAY(), "y")

在这种情况下，不需要额外的舍入功能，因为具有“ Y”单元的日期公式可以计算全年数量：

如何在几年，几个月和几天内从生日开始年龄

正如您刚刚看到的那样，将年龄计算为该人寿命的全年数量很容易，但这并不总是足够的。如果您想知道确切的年龄，即某人的出生日期和当前日期之间有多少年，几个月和几天，请写3个不同的日期功能：

1. 要获得年数： =DATEDIF(B2, TODAY(), "Y")
2. 要获取月数： =DATEDIF(B2, TODAY(), "YM")
3. 要获取天数： =DATEDIF(B2,TODAY(),"MD")

其中B2是出生日期。

然后，将上述功能加入单个公式，例如：

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

上面的公式返回以单个文本字符串连接的3个数字（年，月和天），如下屏幕截图所示：

没什么意义，呃？为了使结果更有意义，请与逗号分开数字并定义每个值的含义：

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

结果现在看起来好多了：

该公式效果很好，但是您可以通过隐藏零值来进一步改进它。为此，添加3个如果检查0的语句，则每个日期为一个：

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

以下屏幕截图证明了动作中最终的Excel年龄公式 - 它在几年，月和天中返回年龄，仅显示非零值：

提示。如果您正在寻找一个excel公式来计算年龄的年龄，请采用上述公式，然后删除计算天数的（日期（））块的最后一个公式。

特定公式以计算Excel年龄

在大多数情况下，上面讨论的通用年龄计算公式效果很好。但是，在某些情况下，您可能需要一些非常具体的东西。当然，不可能涵盖每种情况，但是以下示例将为您提供一些有关如何根据您的特定任务调整年龄公式的想法。

如何计算Excel中特定日期的年龄

如果您想在某个日期了解某人的年龄，请使用上面讨论的日期年龄公式，但用特定日期替换2 ^nd参数中的today（）函数。

假设出生日期在B1中，以下公式将截至2020年1月1日返回年龄：

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

为了使您的年龄公式更加灵活，您可以在某个单元格中输入日期，并在公式中引用该单元格：

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

其中B1是DOB，而B2是您要计算年龄的日期。

计算一年的年龄

在未定义要计算的完整日期的情况下，此公式派上用场，您只知道一年。

假设您正在使用医疗数据库，而您的目标是在接受最后一次完整的医学检查时找出患者的年龄。

假设出生日期是从第3行开始的B列，最后一次医学检查的年份是在C列中，则年龄计算公式如下：

=DATEDIF(B3,DATE(C3, 1, 1),"y")

由于未定义医学检查的确切日期，因此您将日期函数使用任意日期和月参数，例如日期（C3，1，1）。

日期函数从单元B3中提取年份，使用您提供的月份和日号（在此示例中为1-JAN），并将该日期传递给日期。结果，截至特定年的1月1日，您会获得患者的年龄：

找出一个人达到N年龄的日期

假设您的朋友出生于1978年3月8日。通常，您只会在该人的生日中增加50年。在Excel中，您使用日期函数进行相同的操作：

=DATE(YEAR(B2) 50, MONTH(B2), DAY(B2))

其中B2是出生日期。

您可以参考用户可以输入任何数年的特定单元格（在下面的屏幕截图中）：

计算不同细胞的日，月和年的年龄

当生日分为3个不同的细胞（例如B3，C3的月份，D3中的一天）时，您可以以这种方式计算年龄：

• 通过使用日期和日期功能来获取出生日期： DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)
• Embed the above formula into DATEDIF to calculate age from date of birth in years, months, and days: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

有关计算日期之前/之后天数的更多示例，请查看如何计算以来或直到Excel中的日期。

Excel中的年龄计算器

如果您想在Excel中拥有自己的年龄计算器，则可以使用下面解释的一些不同的日期公式来制作一个。如果您不想重新发明轮子，则可以使用我们Excel专业人员创建的年龄计算器。

如何在Excel中创建年龄计算器

现在您知道如何在Excel中制作一个年龄公式，可以构建自定义年龄计算器，例如：

笔记。要查看嵌入式工作簿，请允许营销饼干。

您在上面看到的是嵌入式excel在线表，因此请随时进入相应的单元格中的生日，您会稍后才能达到年龄。

计算器使用以下公式根据细胞A3和今天的日期根据出生日期来计算年龄。

• B5中的公式计算年度，月和天的年龄： =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• B6中的公式计算几个月的年龄： =DATEDIF($B$3,TODAY(),"m")
• B7中的公式在天数中计算年龄： =DATEDIF($B$3,TODAY(),"d")

如果您在Excel表单控件方面有一定的经验，则可以在特定日期添加一个选项以计算年龄，如以下屏幕截图所示：

为此，添加几个选项按钮（开发人员选项卡>插入>表单控件>选项按钮），然后将它们链接到某些单元格。然后，编写一个if/netatedif公式，以在今天的日期或用户指定的日期中年龄。

该公式可与以下逻辑合作：

• 如果选择了今天的日期选项框，则值1将出现在链接的单元格（i5）中，并且年龄公式根据今天的日期计算： IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• If the Specific date option button is selected AND a date is entered in cell B7, age is calculated at the specified date: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

最后，将上述功能相互嵌套，您将获得完整的年龄计算公式（在B9中）：

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

B10和B11中的公式具有相同的逻辑。当然，它们要简单得多，因为它们仅包含一个日期的功能，分别作为完整的月份或几天的数量返回年龄。

要了解详细信息，我邀请您下载此Excel年龄计算器，并研究单元格B9：B11中的公式。

下载Excel的年龄计算器

Excel的现成年龄计算器

我们的Ultimate Suite的用户不必费心在Excel中制作自己的年龄计算器 - 只需单击几下：

1. 选择要插入年龄公式的单元格，转到“ ablebits工具”选项卡>日期和时间组，然后单击日期和时间向导按钮。

   

2. 日期和时间向导将开始，您直接转到“年龄”选项卡。
3. 在“年龄”选项卡上，您有3件事可以指定：
   • 以MM/DD/YYYY格式出生的数据作为细胞参考或日期。
   • 今天的日期或特定日期。
   • 选择是否计算几天，几个月，年或确切年龄的年龄。
4. 单击插入公式按钮。

完毕！

该公式会暂时插入选定的单元格中，然后双击填充手柄以将其复制到列下。

您可能已经注意到，我们的Excel年龄计算器创建的公式比到目前为止讨论的公式更为复杂，但它可以符合“ day”和“ Days”等时间单元的单数和复数单位。

如果您想摆脱“ 0天”之类的零单位，请选择“不显示零单元”复选框：

如果您想测试这个年龄计算器，并发现Excel的60个节省时间的加载项，欢迎您在本文结尾处下载我们的Ultimate Suite的试用版。

如何突出某些年龄（在特定年龄以下）

在某些情况下，您可能不仅需要计算Excel的年龄，还需要突出显示包含特定年龄以下年龄的细胞。

如果您的年龄计算公式返回完整年的数量，则可以根据类似的简单公式创建常规条件格式规则：

• 突出显示年龄等于或大于18：= $ c2> = 18
• 突出显示18岁以下的年龄：= $ c2

其中C2是年龄柱中最高的单元格（不包括列标题）。

但是，如果您的公式在数年，几个月或几年，几个月和几天中显示年龄怎么办？在这种情况下，您将必须根据日期公式创建一个规则，该公式从年来计算出生日期。

假设出生日期是从第2行开始的B列，则公式如下：

• 突出显示18岁以下的年龄（黄色）： =DATEDIF($B2, TODAY(),"Y")
• 突出显示18至65岁（绿色）的年龄： =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")
• 突出显示65岁以上的年龄（蓝色）： =DATEDIF($B2, TODAY(),"Y")>65

要根据上述公式创建规则，请选择要突出显示的单元格或整个行，请转到“ Home Tab”> “样式组”，然后单击条件格式>新规则… >使用公式来确定要格式化的单元格。

可以在此处找到详细的步骤：如何根据公式制定条件格式规则。

这就是您在Excel中计算年龄的方式。我希望公式可以轻松学习，您会在工作表中尝试一下。感谢您的阅读，并希望下周在我们的博客上见到您！

可用下载

Excel年龄计算示例（.xlsx文件）Ultimate Suite 14天功能版本（.EXE文件）

以上是如何计算生日的年龄的详细内容。更多信息请关注PHP中文网其他相关文章！